# $Id: PKGBUILD 36467 2009-04-23 02:40:34Z eric $
#  ppc Maintainer: Alexander Baldeck <alexander@archlinux.org>
# i686 Maintainer: Jan de Groot <jgc@archlinux.org>
pkgname=xterm
pkgver=243
pkgrel=2
pkgdesc="X Terminal Emulator"
arch=(arm)
url="http://invisible-island.net/xterm/"
license=('custom')
depends=('libxft' 'libxaw>=1.0.5' 'ncurses' 'xorg-apps')
groups=('xorg')
source=(ftp://invisible-island.net/${pkgname}/${pkgname}-${pkgver}.tgz LICENSE)
md5sums=('be25d2d3661d0bb77fc66e1bcbb3caba' '10ecc3f8ee91e3189863a172f68282d2')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  ./configure --prefix=/usr \
              --libdir=/etc \
              --mandir=/usr/share/man \
	      --with-app-defaults=/usr/share/X11/app-defaults/ \
              --with-x \
	      --disable-full-tgetent \
	      --disable-imake \
	      --enable-ansi-color \
	      --enable-88-color \
	      --enable-256-color \
	      --enable-broken-osc \
	      --enable-broken-st \
	      --enable-load-vt-fonts \
	      --enable-i18n \
	      --enable-wide-chars \
	      --enable-doublechars \
	      --enable-warnings \
	      --enable-tcap-query \
	      --enable-logging \
	      --enable-dabbrev \
	      --enable-freetype \
	      --enable-luit \
	      --enable-mini-luit \
	      --enable-narrowproto || return 1
  make || return 1
  make DESTDIR="${pkgdir}" install || return 1
  install -D -m644 ../LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
  chmod 0755 "${pkgdir}/usr/bin/xterm" || return 1
}