# Maintainer: Kevin Mihelich <kevin@archlinuxarm.org>
# Contributor: Kiril Zyapkov <kiril.zyapkov@gmail.com>

# U-Boot for i.MX233-OLinuXino

buildarch=2

pkgname=uboot-olinuxino
pkgdesc="U-Boot for i.MX233-OLinuXino"
pkgver=2013.04
pkgrel=2
arch=('arm')
license=('GPL')
depends=('coreutils')
makedepends=('git' 'elftosb')
install=$pkgname.install
options=('!strip')
source=("ftp://ftp.denx.de/pub/u-boot/u-boot-${pkgver}.tar.bz2"
        '0001-imx-Move-some-header-files-from-arch-mxs-to-imx-comm.patch'
        '0002-mxs-mxsboot-Move-sdcard-BCB-header-to-4-sectors-offs.patch'
        '0003-mx23-Put-back-RAM-voltage-level-to-its-original-valu.patch'
        '0004-mx23-Fix-pad-voltage-selection-bit.patch'
        '0005-mx23_olinuxino-Fix-DDR-pin-iomux-settings.patch'
        '0006-mxs-spl_mem_init-Fix-comment-about-start-bit.patch'
        '0007-mxs-spl_mem_init-Remove-erroneous-DDR-setting.patch'
        '0008-mxs-spl_mem_init-Skip-the-initialization-of-some-DRA.patch'
        '0009-mxs-spl_mem_init-Change-EMI-port-priority.patch'
        '0010-mx23-Operate-DDR-voltage-supply-at-2.5V.patch'
        '0011-mx23_olinuxino-Do-not-set-voltage-selection-bit-for-.patch'
        '0012-mxs-Explain-why-some-mx23-DDR-registers-are-not-conf.patch'
        '0013-arm-mx23-Fix-VDDMEM-misconfiguration.patch'
        '0014-arm-mxs-Preprocess-u-boot.bd-so-they-contain-full-pa.patch'
        '0015-Add-generic-and-ext4-commands-adjust-boot-environmen.patch'
        '0016-mx23_olinuxino-Add-bootz-command.patch')
md5sums=('21bf962d69938ed4ed783b792b2b074e'
         '93746f9682fb56a3cbbbcc9e6389bc8a'
         '29412096225ca8eed21f205d0a9dfe14'
         '7fad77467166d87ce875c9d4eebfcf35'
         'cabb9ff2cf4cbeec0aa1b161be242233'
         '7aa7399910fe9670f8eb673f2615d6ab'
         'e3a4d5678ff726dcd9fe78c23716f95c'
         'cd6c109e1cc19986993a626e45e49d08'
         'a3e9a69ee26f21c03c93e7f7c6fb432e'
         'cca5cb6d7684c46bcdcdb3352dc1bc20'
         'be99aba7a08edd410c1c0d64115e6b58'
         'd1a42119f38d6dd98b3bc5a576f4697b'
         '38df690f2b10dda11b771a4753434fe5'
         '5df3f02303f158bd0bf449c2e2ae86fc'
         'a5995f5be9ca0f5956ebc4d95559da21'
         'cb1d955bb42c58d0ef683f7e74178095'
         'ae8def5b8d1916f71ba632934cf83c26')

prepare() {
  cd "$srcdir/u-boot-${pkgver}"
  
  patch -Np1 -i $srcdir/0001-imx-Move-some-header-files-from-arch-mxs-to-imx-comm.patch
  patch -Np1 -i $srcdir/0002-mxs-mxsboot-Move-sdcard-BCB-header-to-4-sectors-offs.patch
  patch -Np1 -i $srcdir/0003-mx23-Put-back-RAM-voltage-level-to-its-original-valu.patch
  patch -Np1 -i $srcdir/0004-mx23-Fix-pad-voltage-selection-bit.patch
  patch -Np1 -i $srcdir/0005-mx23_olinuxino-Fix-DDR-pin-iomux-settings.patch
  patch -Np1 -i $srcdir/0006-mxs-spl_mem_init-Fix-comment-about-start-bit.patch
  patch -Np1 -i $srcdir/0007-mxs-spl_mem_init-Remove-erroneous-DDR-setting.patch
  patch -Np1 -i $srcdir/0008-mxs-spl_mem_init-Skip-the-initialization-of-some-DRA.patch
  patch -Np1 -i $srcdir/0009-mxs-spl_mem_init-Change-EMI-port-priority.patch
  patch -Np1 -i $srcdir/0010-mx23-Operate-DDR-voltage-supply-at-2.5V.patch
  patch -Np1 -i $srcdir/0011-mx23_olinuxino-Do-not-set-voltage-selection-bit-for-.patch
  patch -Np1 -i $srcdir/0012-mxs-Explain-why-some-mx23-DDR-registers-are-not-conf.patch
  patch -Np1 -i $srcdir/0013-arm-mx23-Fix-VDDMEM-misconfiguration.patch
  patch -Np1 -i $srcdir/0014-arm-mxs-Preprocess-u-boot.bd-so-they-contain-full-pa.patch
  patch -Np1 -i $srcdir/0015-Add-generic-and-ext4-commands-adjust-boot-environmen.patch
  patch -Np1 -i $srcdir/0016-mx23_olinuxino-Add-bootz-command.patch
}

build() {
  cd "$srcdir/u-boot-${pkgver}"

  make mx23_olinuxino_config
  make u-boot.sb
}

package() {
  mkdir -p "${pkgdir}/opt/uboot-olinuxino"
  cp "$srcdir/u-boot-$pkgver/u-boot.sb" "${pkgdir}/opt/uboot-olinuxino"
}