# Maintainer: Thayer Williams <thayer@archlinux.org>
# Contributor: Giovanni Scafora <giovanni@archlinux.org>

pkgname=pm-utils
pkgver=1.2.6.1
pkgrel=4
pkgdesc="Utilities and scripts for suspend and hibernate power management"
arch=(arm)
url="http://pm-utils.freedesktop.org"
license=('GPL')
depends=('bash' 'procps')
makedepends=('xmlto')
source=(http://pm-utils.freedesktop.org/releases/${pkgname}-${pkgver}.tar.gz
        11netcfg
       	daemons.patch
        nouveau.patch)
md5sums=('ddbb73b5fd1e5a2c77ad3ce537a0260c'
         '9839687c8787d99fd4ff36aa3238c27b'
         '7be3f7460569d5a382474abd7f7b53fb'
         '6300409fcc96d70fd2a2e2efeff19f79')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  # temp fix for nouveau power management--will be fixed in next release
  patch -Np1 -i ${srcdir}/nouveau.patch || return 1

  # make sure Arch Linux daemons are properly handled
  patch -Np1 -i ${srcdir}/daemons.patch || return 1

  ./configure --prefix=/usr \
              --sysconfdir=/etc \
              --localstatedir=/var
  make || return 1
  make DESTDIR=${pkgdir} install || return 1

  # install additional hooks
  install -m755 ${srcdir}/11netcfg "${pkgdir}/usr/lib/pm-utils/sleep.d/11netcfg"
}