# $Id: PKGBUILD 90828 2013-05-14 12:04:07Z arodseth $
# Maintainer: Alexander Rødseth <rodseth@gmail.com>
# Contributor: Jan de Groot <jgc@archlinux.org>
# Contributor: Jan Steffens <heftig@archlinux.org>

# Kevin Mihelich <kevin@archlinuxarm.org>
#  - fix for aeskey.c on ARM (http://wiki.powerdns.com/trac/changeset/3162/)

pkgname=pdns-recursor
pkgver=3.5
pkgrel=2
pkgdesc='PowerDNS recursor'
url='https://www.powerdns.com/'
license=('GPL')
arch=('x86_64' 'i686')
depends=('gcc-libs' 'lua51')
makedepends=('boost')
backup=('etc/powerdns/recursor.conf')
source=("http://downloads.powerdns.com/releases/$pkgname-$pkgver.tar.bz2"
        'pdns-recursor.service'
        'arm.patch')
sha256sums=('02ea398aa0e95ef4c9caf478eb3836598eabcd5c99ccb7e2e7c265d716089549'
            '51688d9576736fdf210048098fa96c8710bfbd6a63eb4d69d20bac57b299b5f9'
            'ff51af1648d6049f58887ca4f84fa41955ab5df8156d8a00b4b3b148e2bd789f')

build() {
  cd "$srcdir/$pkgname-$pkgver"

  patch -p5 -i "$srcdir/arm.patch"

  make LUA=1 \
    LUA_CPPFLAGS_CONFIG="$(pkg-config --cflags lua5.1)" \
    LUA_LIBS_CONFIG="$(pkg-config --libs lua5.1)"
}

package() {
  cd "$srcdir/$pkgname-$pkgver"

  make SBINDIR="/usr/bin" DESTDIR="$pkgdir" install
  mv "$pkgdir/etc/powerdns/recursor.conf-dist" "$pkgdir/etc/powerdns/recursor.conf"
  rm -r "$pkgdir/etc/init.d"
  install -Dm644 "$srcdir/pdns-recursor.service" \
    "$pkgdir/usr/lib/systemd/system/pdns-recursor.service"
}

# vim:set ts=2 sw=2 et: