# Maintainer: judd <jvinet@zeroflux.org>

pkgname=freetype2
pkgver=2.3.9
pkgrel=2
pkgdesc="TrueType font rendering library"
arch=('arm')
license=('GPL')
url="http://freetype.sourceforge.net"
depends=('zlib')
options=('!libtool')
source=(http://downloads.sourceforge.net/sourceforge/freetype/freetype-${pkgver}.tar.bz2
	bytecode.patch
	freetype-2.3.0-enable-spr.patch
	freetype-2.2.1-enable-valid.patch
	freetype-2.2.1-memcpy-fix.patch
	CVE-2009-0946.patch)
md5sums=('d76233108aca9c9606cdbd341562ad9a'
         '9ff19e742968c29e3ba52b08d6bf0a50'
         '816dc8619a6904a7385769433c0a8653'
         '214119610444c9b02766ccee5e220680'
         '6fb6606d28082ecb8e0c6d986b0b26aa'
 	 '3322c8f8266f7f3dcafb7205ad433c05')

build() {
  cd "${srcdir}/freetype-${pkgver}"
  patch -Np0 -i "${srcdir}/bytecode.patch" || return 1
  patch -Np1 -i "${srcdir}/freetype-2.3.0-enable-spr.patch" || return 1
  patch -Np1 -i "${srcdir}/freetype-2.2.1-enable-valid.patch" || return 1
  patch -Np1 -i "${srcdir}/freetype-2.2.1-memcpy-fix.patch" || return 1
  patch -Np1 -i "${srcdir}/CVE-2009-0946.patch" || return 1

  CFLAGS="-std=gnu99" ./configure --prefix=/usr || return 1
  make || return 1
  make DESTDIR="${pkgdir}" install || return 1
}