# $Id$
# Maintainer: Sven-Hendrik Haase <sh@lutzhaase.com>

# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
#  - removed intel-tbb from deps
#  - set -DUSE_LLVM_BITCODE=OFF for v5 and v6

pkgname=openshadinglanguage
pkgver=1.5.10
pkgrel=2
pkgdesc="Advanced shading language for production GI renderers"
arch=(i686 x86_64)
url="https://github.com/imageworks/OpenShadingLanguage"
license=('custom')
depends=('boost-libs' 'openimageio' 'openexr' 'llvm' 'freetype2' 'libpng' 'libtiff')
makedepends=('boost' 'cmake' 'clang')
source=(https://github.com/imageworks/OpenShadingLanguage/archive/Release-${pkgver}.tar.gz
        https://github.com/imageworks/OpenShadingLanguage/commit/163df11a3af32295757cfe008d1ba2b757cc7b7b.patch
        https://github.com/imageworks/OpenShadingLanguage/pull/412.patch)
md5sums=('b828366f056e115b539ee1780883fc7d'
         'e980ed0a9480958307fa048544154887'
         'd21cab675ce13c9f0640e1f6a662d2b9')

build() {
  cd OpenShadingLanguage-Release-$pkgver

  # Fails building this file on i686
  #sed -i "/src\/testshade/d" CMakeLists.txt

  patch -Np1 < $srcdir/412.patch
  patch -Np1 < $srcdir/163df11a3af32295757cfe008d1ba2b757cc7b7b.patch

  cd src

  [[ -d build ]] && rm -r build
  mkdir build && cd build

  [ "${CARCH}" == "arm" -o "${CARCH}" == "armv6h" ] && BITCODE="-DUSE_LLVM_BITCODE=OFF"

  cmake ../.. \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DLLVM_STATIC=0 ${BITCODE} \
    -DSTOP_ON_WARNING=0 \
    -DCMAKE_CXX_FLAGS="-std=c++11"
  make
}

package() {
  cd OpenShadingLanguage-Release-$pkgver/src/build

  make DESTDIR="$pkgdir/" install

  mkdir -p "$pkgdir"/usr/share/OSL/
  mkdir -p "$pkgdir"/usr/share/licenses/$pkgname
  mv "$pkgdir"/usr/LICENSE "$pkgdir"/usr/share/licenses/$pkgname # TODO: Tell upstream about this shit
  mv "$pkgdir"/usr/{CHANGES,README.md,INSTALL} "$pkgdir"/usr/share/OSL/
  mv "$pkgdir"/usr/doc "$pkgdir"/usr/share/OSL/doc
  mv "$pkgdir"/usr/shaders "$pkgdir"/usr/share/OSL/shaders
}

# vim:set ts=2 sw=2 et: