# $Id: PKGBUILD 54213 2009-10-07 10:18:13Z andrea $
# Maintainer: Pierre Schmitz <pierre@archlinux.de>

pkgbase=kdemultimedia
pkgname=('kdemultimedia-dragonplayer'
         'kdemultimedia-juk'
         'kdemultimedia-kioslave'
         'kdemultimedia-kmix'
         'kdemultimedia-kscd'
         'kdemultimedia-mplayerthumbs')
pkgver=4.3.2
pkgrel=1
arch=('i686' 'x86_64')
url='http://www.kde.org'
license=('GPL' 'LGPL' 'FDL')
groups=('kde' 'kdemultimedia')
makedepends=('pkgconfig' 'cmake' 'automoc4' 'kdelibs' 'kdelibs-experimental' 'kdebase-runtime' 'tunepimp' 'cdparanoia' 'mplayer')
source=("http://download.kde.org/stable/${pkgver}/src/${pkgbase}-${pkgver}.tar.bz2"
        'mplayerthumbs.config')
md5sums=('c32305e0d17198387a495e75f3d844ac'
         '698c1579905135043dcdd4dbe55f2c7e')

build() {
	cd $srcdir
	mkdir build
	cd build
	cmake ../${pkgbase}-${pkgver} \
		-DCMAKE_BUILD_TYPE=Release \
		-DCMAKE_SKIP_RPATH=ON \
		-DCMAKE_{SHARED,MODULE,EXE}_LINKER_FLAGS='-Wl,--no-undefined -Wl,--as-needed' \
		-DCMAKE_INSTALL_PREFIX=/usr \
		-DWITH_Xine=OFF \
		-DWITH_PulseAudio=OFF
	make
}

package_kdemultimedia-dragonplayer() {
	pkgdesc='Video Player'
	depends=('kdelibs' 'kdebase-runtime')
	install='kdemultimedia.install'
	cd $srcdir/build/dragonplayer
	make DESTDIR=$pkgdir install
	cd $srcdir/build/doc/dragonplayer
	make DESTDIR=$pkgdir install
}

package_kdemultimedia-juk() {
	pkgdesc='Music Player'
	depends=('kdelibs' 'kdebase-runtime' 'tunepimp')
	install='kdemultimedia.install'
	cd $srcdir/build/juk
	make DESTDIR=$pkgdir install
	cd $srcdir/build/doc/juk
	make DESTDIR=$pkgdir install
}

package_kdemultimedia-kioslave() {
	pkgdesc='Audio CD Browser'
	depends=('kdelibs' 'flac' 'musicbrainz')
	conflicts=('kdemultimedia-libkcddb' 'kdemultimedia-libkcompactdisc')
	replaces=('kdemultimedia-libkcddb' 'kdemultimedia-libkcompactdisc')
	for i in kioslave doc/kioslave libkcddb libkcompactdisc; do
		cd $srcdir/build/${i}
		make DESTDIR=$pkgdir install
	done
}

package_kdemultimedia-kmix() {
	pkgdesc='Sound Mixer'
	depends=('kdelibs-experimental' 'kdebase-runtime')
	install='kdemultimedia.install'
	cd $srcdir/build/kmix
	make DESTDIR=$pkgdir install
	cd $srcdir/build/doc/kmix
	make DESTDIR=$pkgdir install
}

package_kdemultimedia-kscd() {
	pkgdesc='CD Player'
	depends=('kdelibs' 'kdebase-runtime' 'musicbrainz')
	install='kdemultimedia.install'
	cd $srcdir/build/kscd
	make DESTDIR=$pkgdir install
	cd $srcdir/build/doc/kscd
	make DESTDIR=$pkgdir install
}

package_kdemultimedia-mplayerthumbs() {
	pkgdesc='Video Files (MPlayerThumbs)'
	depends=('kdelibs' 'kdebase-runtime' 'mplayer')
	replaces=('mplayerthumbs')
	conflicts=('mplayerthumbs')
	cd $srcdir/build/mplayerthumbs
	make DESTDIR=$pkgdir install
	install -D -m644 $srcdir/mplayerthumbs.config $pkgdir/usr/share/config/mplayerthumbs
}