# Maintainer: Jouke Witteveen <j.witteveen@gmail.com>

pkgname=netctl
pkgver=0.5
pkgrel=1
arch=(any)
pkgdesc="Network configuration and profile scripts"
url="http://projects.archlinux.org/netctl.git/"
license=("GPL")
depends=("coreutils" "iproute2" "openresolv")
makedepends=('asciidoc')
optdepends=('dialog: for the menu based wifi assistant'
            'dhclient: for DHCP support, or use dhcpcd'
            'dhcpcd: for DHCP support, or use dhclient'
            'wpa_supplicant: for wireless networking support'
            'ifplugd: for automatic wired connections through netctl-ifplugd'
            'wpa_actiond: for automatic wireless connections through netctl-auto'
            'ifenslave: for bond connections'
            'bridge-utils: for bridge connections'
            )
conflicts=("netcfg")
provides=("netcfg")

source=(ftp://ftp.archlinux.org/other/packages/netctl/netctl-${pkgver}.tar.xz)
arch=(any)
md5sums=('9ceeb6de07e8cb80a218bdb7920edd98')

package() {
	cd "$srcdir/netctl-${pkgver}"
	make DESTDIR="$pkgdir" install

	# Shell Completion
	install -D -m644 contrib/bash-completion "$pkgdir/usr/share/bash-completion/completions/netctl"
	install -D -m644 contrib/zsh-completion "$pkgdir/usr/share/zsh/site-functions/_netctl"
}