# $Id: PKGBUILD 52467 2009-09-20 08:36:28Z daniel $
# Maintainer: Daniel Isenmann <daniel@archlinux.org>
# Contributor: Rashif "Don Ray" Rahman <rayrashif@gmail.com>

pkgname=wicd
pkgver=1.6.2.2
pkgrel=2
pkgdesc="New and alternative wireless/wired network management utility"
arch=('i686' 'x86_64')
url="http://wicd.sourceforge.net/"
license=('GPL2')
depends=('python' 'dbus-python' 'pygtk' 'dhcpcd' 'wpa_supplicant' 'wireless_tools' 'ethtool' 'shared-mime-info' 'python-urwid')
optdepends=('hicolor-icon-theme'
            'gksu:		needed to access some preferences in gtk interface'
            'notification-daemon: needed if you want notifications'
            'python-notify:	needed if you want notifications'
            'python-wpactrl:	needed if you want to use the new experimental ioctrl backend'
	    'python-iwscan:	needed if you want to use the new experimental ioctrl backend')
conflicts=('wicd-svn')
install=wicd.install
source=(http://downloads.sourceforge.net/sourceforge/$pkgname/$pkgname-$pkgver.tar.gz
        wicd-daemon
        wicd.desktop)
options=('emptydirs')
backup=('etc/wicd/encryption/templates/active')
md5sums=('acbbe695abf7ff83161c62317dfc7509'
         'f40e5f59998d0829707a7c9976afa8f8'
         '60636b904efedb5f1b04b39747b16342')

build() {
  cd $srcdir/$pkgname-$pkgver
  python setup.py configure --no-install-init --resume=/usr/share/wicd/scripts/ \
                            --suspend=/usr/share/wicd/scripts/ --verbose
  python setup.py install --root=$pkgdir

  # Add custom rc.d script
  install -Dm755 $srcdir/wicd-daemon $pkgdir/etc/rc.d/wicd
  install -Dm644 $srcdir/wicd.desktop $pkgdir/usr/share/applications/wicd.desktop

  cd build/lib/wicd
  for i in *.py; do
    install -Dm 755 $i $startdir/pkg/usr/lib/wicd/$i
  done
  
  rm -rf  ${startdir}/pkg/usr/share/autostart
}