# $Id: PKGBUILD 22213 2008-12-23 06:35:19Z eric $
# Maintainer: Arjan Timmerman <arjan@archlinux.org>
# Contributor: Tom Newsom <Jeepster@gmx.co.uk>

pkgname=xbill
pkgver=2.1
pkgrel=6
pkgdesc="Xbill is a game that tests you reflexes as you seek and destroy all forms of Bill"
arch=('i686' 'x86_64')
url="http://www.xbill.org/"
license=('GPL')
depends=('xaw3d>=1.5E' 'libxaw')
install=xbill.install
source=(http://www.xbill.org/download/$pkgname-$pkgver.tar.gz)
md5sums=('585e4866b15255a24203db9959407b2f')

build() {
  cd $srcdir/$pkgname-$pkgver
  ./configure --prefix=/usr --mandir=/usr/share/man --localstatedir=/var/games \
  --disable-motif  --enable-athena --disable-gtk || return 1
  make || return 1
  make DESTDIR=$pkgdir install || return 1

# set appropriate permissions and destinations
  chown root:games $pkgdir/usr/bin/xbill
  chmod 2755 $pkgdir/usr/bin/xbill

  chown root:games $pkgdir/var/games
  chmod 775 $pkgdir/var/games
  chown root:games $pkgdir/var/games/xbill
  chmod 775 $pkgdir/var/games/xbill

# Handle the scores file creation in the install script
  rm $pkgdir/var/games/xbill/scores
}