# $Id$
# Maintainer: Andreas Radke <andyrtr@archlinux.org>
# Contributor: Art Gramlich <art@gramlich-net.com>

# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
#  - patch to fix icudata library linking on ARM

pkgname=icu
pkgver=58.1
pkgrel=2
pkgdesc="International Components for Unicode library"
arch=(i686 x86_64)
url="http://www.icu-project.org/"
license=('custom:icu')
depends=('gcc-libs>=4.7.1-5' 'sh')
#makedepends=('clang')
# no https available
source=(#http://download.icu-project.org/files/${pkgname}4c/${pkgver}/${pkgname}4c-${pkgver/./_}-src.tgz
	http://download.icu-project.org/files/${pkgname}4c/${pkgver}/${pkgname}4c-${pkgver//./_}-src.tgz
	icu-58.1-iterator-reset.patch
	icudata-stdlibs.patch)
#	icu.8198.revert.icu5431.patch)
# upstream offers md5sum checks, only asc file for md5sum check
md5sums=('1901302aaff1c1633ef81862663d2917'
         '8c09ae284967def053e9579d64d0f83c'
         '4e5202245fce364490334bd66b5edabc')
#         'ebd5470fc969c75e52baf4af94a9ee82')

prepare() {
  cd icu/source

# that file is no more present in current release, asume the bug to be fixed.
#  # fix Malayalam encoding https://bugzilla.redhat.com/show_bug.cgi?id=654200
#  patch -Rp3 -i ${srcdir}/icu.8198.revert.icu5431.patch

  # http://bugs.icu-project.org/trac/ticket/12827
  patch -Np4 -i ${srcdir}/icu-58.1-iterator-reset.patch
  patch -p2 -i ${srcdir}/icudata-stdlibs.patch
}

build() {
  cd icu/source
  ./configure --prefix=/usr \
	--sysconfdir=/etc \
	--mandir=/usr/share/man \
	--sbindir=/usr/bin
  make
}

check() {
  cd icu/source
  make -k check # passes all
}

package() {
  cd icu/source
  make -j1 DESTDIR=${pkgdir} install

  # Install license
  install -Dm644 ${srcdir}/icu/license.html ${pkgdir}/usr/share/licenses/icu/license.html
}