# $Id$
# Maintainer: Sébastien Luttringer
# Contributor: Joel Teichroeb <joel@teichroeb.net>

# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
#  - export flags for rpi

pkgname=weston
pkgver=1.2.0
pkgrel=2.1
pkgdesc='Reference implementation of a Wayland compositor'
arch=('i686' 'x86_64')
url='http://wayland.freedesktop.org'
license=('MIT')
options=(!libtool)
depends=('libxkbcommon' 'libunwind' 'poppler-glib' 'mtdev' 'libxcursor' 'glu' 'pango' 'colord')
source=("http://wayland.freedesktop.org/releases/$pkgname-$pkgver.tar.xz")
sha1sums=('23201d31e71768e5ec3de0d10fa6de988dd273c8')

build() {
	cd $pkgname-$pkgver
	if [ "$CARCH" == 'armv6h' ]; then
		export RPI_BCM_HOST_LIBS="-L/opt/vc/lib"
		export RPI_BCM_HOST_CFLAGS="-I/opt/vc/include -I/opt/vc/include/interface/vcos/pthreads -I/opt/vc/include/interface/vmcs_host/linux"
	fi
	./configure \
		--prefix=/usr \
		--libexecdir=/usr/lib/weston
	make
}

package() {
	cd $pkgname-$pkgver
	make DESTDIR="$pkgdir" install
	# license
	install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
	# embed more clients
	for _c in calibrator clickdot cliptest dnd editor eventdemo flower fullscreen gears \
         image resizor simple-egl simple-shm simple-touch smoke transformed view; do
		install -Dm755 "clients/$_c" "$pkgdir/usr/bin/weston-$_c"
	done
}