# $Id: PKGBUILD 3325 2009-10-02 11:40:00Z rvanharen $
# Maintainer: Ronald van Haren <ronald.archlinux.org>
# Contributor: Ronald van Haren <ronald.archlinux.org>
pkgname=e-svn
pkgver=42849
pkgrel=1
pkgdesc="Enlightenment window manager DR17 (aka e17)"
arch=('i686' 'x86_64')
groups=('e17-svn')
url="http://www.enlightenment.org"
license=('BSD')
depends=('e_dbus-svn' 'edje-svn' 'efreet-svn' 'alsa-lib')
makedepends=('svn' 'cvs')
conflicts=('e')
provides=('e')
replaces=('e-cvs')
backup=('etc/enlightenment/sysactions.conf')
options=('!libtool')
source=()
md5sums=()

_svntrunk="http://svn.enlightenment.org/svn/e/trunk/e"
_svnmod="e"

build() {
   cd $srcdir

msg "Connecting to $_svntrunk SVN server...."
  if [ -d $_svnmod/.svn ]; then
    (cd $_svnmod && svn up -r $pkgver)
  else
    svn co $_svntrunk --config-dir ./ -r $pkgver $_svnmod
  fi

  msg "SVN checkout done or server timeout"
  msg "Starting make..."

  cp -r $_svnmod $_svnmod-build
  cd $_svnmod-build
  
  ./autogen.sh --prefix=/usr --sysconfdir=/etc
  make || return 1
  make DESTDIR=$pkgdir install || return 1

# install license files
  install -Dm644 $srcdir/$_svnmod-build/COPYING \
  	$pkgdir/usr/share/licenses/$pkgname/COPYING
  	
  install -Dm644 $srcdir/$_svnmod-build/COPYING-PLAIN \
  	$pkgdir/usr/share/licenses/$pkgname/COPYING-PLAIN
      
  rm -r $srcdir/$_svnmod-build
}