# Maintainer: Ronald van Haren <ronald.archlinux.org>
# Contributor: Claudio Riva <firetux83@gmail.com>

pkgname=emesene
pkgver=1.5
pkgrel=3
pkgdesc="A pygtk MSN Messenger client"
url="http://www.emesene.org/"
license=('custom:PSF' 'GPL' 'LGPL2.1')
arch=('i686' 'x86_64') # libmimic is hardcoded, so no 'any' package
depends=('python' 'pygtk' 'hicolor-icon-theme' 'xdg-utils')
optdepends=('gnome-python-extras: spell-check plugin'
	'gtkspell: spell-check plugin'
	'aspell: spell-check plugin (also need aspell dictionary)'
	'gstreamer0.10-python: webcam support')
source=(http://downloads.sourceforge.net/sourceforge/${pkgname}/${pkgname}-$pkgver.tar.gz \
	'emesene.run' 'setup.patch')
install=emesene.install
options=('!libtool')
md5sums=('b7dffa8f113ab1f3b90e3e2a48001007'
         '9b777e7b447bbefce7c3d97841a86d4c'
         '1a1a8c48a7473901e95440e17352e874')
            
build() {
  cd ${srcdir}/${pkgname}-${pkgver}
  
  # enable installing in setup.py
  patch -Np0 -i ${srcdir}/setup.patch || return 1

  # install license files
  install -Dm644 COPYING ${pkgdir}/usr/share/licenses/emesene/COPYING
  install -Dm644 PSF ${pkgdir}/usr/share/licenses/emesene/PSF
  
  # install files
  python setup.py install --prefix=${pkgdir}/usr

  # use /usr/share/emesene instead of /usr/lib/python2.5/site-packages
  mv -f ${pkgdir}/usr/lib/python2.6/site-packages $pkgdir/usr/share/emesene
  rm -rf ${pkgdir}/usr/lib
  
  # remove old executable and use our own because we use /usr/share/emesene
  rm ${pkgdir}/usr/bin/emesene
  install -Dm755 ${srcdir}/emesene.run ${pkgdir}/usr/bin/emesene
}