# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Maintainer: Remi Gacogne <rgacogne[at]archlinux[dot]org>
# Contributor: Alexander Rødseth <rodseth@gmail.com>
# Contributor: Jan de Groot <jgc@archlinux.org>
# Contributor: Jan Steffens <heftig@archlinux.org>

# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
#  - remove makedepend on pandoc

pkgname=powerdns-recursor
pkgver=4.6.1
pkgrel=1
pkgdesc='Resolving DNS server'
url='https://www.powerdns.com/'
arch=('x86_64')
license=('GPL2')
depends=('gcc-libs' 'boost-libs' 'libcurl.so' 'libsodium' 'systemd-libs' 'luajit' 'openssl'
         'libboost_context.so' 'fstrm' 'net-snmp')
makedepends=('boost' 'ragel' 'systemd')
provides=('pdns-recursor')
conflicts=('pdns-recursor')
backup=('etc/powerdns/recursor.conf')
source=(https://downloads.powerdns.com/releases/pdns-recursor-${pkgver}.tar.bz2{,.asc}
        openssl-3.0.patch::https://github.com/PowerDNS/pdns/commit/fd91586b4f6d21c65ff47b7c82348a6885b81e83.diff
        sysusers.conf)
sha512sums=('b595dd382bb4bff5cd47bff854952c8ee40bedeafe4236f935c8eceeca7ac97e8668b884e1ec0ce490ce535fab10d161ffc53ca395c0bb02ffcf6005a692674b'
            'SKIP'
            'f180ae8111244f3a0faf884f6f5997b1fcef0eefa30c154d7d44bd2948acdfd742cb4e2410f0855579f36c02e39a3afab6966661d4201400ebc191c5b669d86e'
            '63b3f0664d38fbbcb6b1c914cee050a27eca0a15550962973743580dd5d3ace2e68272ca2d856d53cc74001fe9246d61207ebbc74524c096736777ed08c88e72')
validpgpkeys=('FBAE0323821C7706A5CA151BDCF513FA7EED19F3'  # Peter van Dijk <peter.van.dijk@powerdns.com>
              '16E12866B7738C73976A57436FFC33439B0D04DF') # Winkels, Erik <erik.winkels@open-xchange.com>

prepare() {
  cd pdns-recursor-${pkgver}
  autoreconf -i
  patch -p2 < ../openssl-3.0.patch
}

build() {
  cd pdns-recursor-${pkgver}
  LIBS=$LIBS ./configure \
    --prefix=/usr \
    --sbindir=/usr/bin \
    --sysconfdir=/etc/powerdns \
    --disable-silent-rules \
    --enable-reproducible \
    --enable-systemd \
    --enable-dns-over-tls \
    --with-libsodium \
    --with-lua=luajit \
    --with-service-user=pdns-recursor \
    --with-service-group=pdns-recursor
  make
}

package() {
  cd pdns-recursor-${pkgver}
  make DESTDIR="${pkgdir}" install
  mv "${pkgdir}/etc/powerdns/recursor.conf"{-dist,}
  install -Dm 644 "${srcdir}/sysusers.conf" "${pkgdir}/usr/lib/sysusers.d/powerdns-recursor.conf"
}

# vim: ts=2 sw=2 et: