# $Id$
# Maintainer: Jonathan Steel <jsteel at archlinux.org>
# Contrinutor: Dan Serban
# Contributor: Franz Burgmann
# Contributor: Todd Partridge (Gen2ly)
# Contributor: Ivan Sichmann Freitas

# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
#  - remove fail-mbr from build

pkgname=partclone
pkgver=0.2.87
pkgrel=2
pkgdesc="Utilities to save and restore used blocks on a partition"
arch=('i686' 'x86_64')
url="http://partclone.org"
license=('GPL')
depends=('progsreiserfs' 'ntfs-3g' 'nilfs-utils')
source=(http://partclone.nchc.org.tw/download/testing/${pkgname}_$pkgver.orig.tar.gz)
md5sums=('e06ffe1bf5ef463937ecb9ac2f38d4fe')

build() {
  cd $pkgname-$pkgver

  sed -i 's/fail-mbr//' Makefile.in
  ./configure --prefix=/usr --enable-extfs --enable-reiserfs --enable-fat \
    --enable-hfsp --enable-btrfs --enable-ncursesw --enable-ntfs \
    --enable-exfat --enable-f2fs --enable-minix --enable-nilfs2 --enable-xfs \
    --sbindir=/usr/bin

  make
}

package() {
  cd $pkgname-$pkgver

  make PREFIX=/usr DESTDIR="$pkgdir" install
}