# Maintainer : Biru Ionut <ionut@archlinux.ro>
# Contributor: Geoffroy Carrier <geoffroy.carrier@aur.archlinux.org>
# Contributor: Andrea Scarpino <bash.lnx@gmail.com>
# Contributor: Roman Kyrylych <roman@archlinux.org>
pkgname=virtualbox-ose-additions-modules
_kernver=2.6.30-ARCH
pkgver=3.0.6
pkgrel=1
pkgdesc="Kernel modules for VirtualBox Guest Additions"
arch=('i686' 'x86_64')
url="http://www.virtualbox.org"
license=('GPL')
depends=('kernel26>=2.6.30' 'kernel26<2.6.31')
install=virtualbox-ose-additions-modules.install
source=(http://download.virtualbox.org/virtualbox/$pkgver/VirtualBox-$pkgver-OSE.tar.bz2)
build() {
  cd "$srcdir/VirtualBox-${pkgver}_OSE/src/VBox/Additions/linux/"
  ./export_modules vboxmodules.tar.gz
  tar -xf vboxmodules.tar.gz
  cd vboxadd
  make || return 1
  install -D -m644 vboxadd.ko \
    "$pkgdir/lib/modules/$_kernver/misc/vboxadd.ko" || return 1
  cd ../vboxvfs
  make || return 1
  install -D -m644 vboxvfs.ko \
    "$pkgdir/lib/modules/$_kernver/misc/vboxvfs.ko" || return  1
  sed -i -e "s/KERNEL_VERSION='.*'/KERNEL_VERSION='${_kernver}'/" \
  "$startdir/$pkgname.install"
}
md5sums=('8249090b4e08ca2eff3efa9f836f370b')