# Maintainer: Kevin Mihelich <kevin@archlinuxarm.org>
# Contributor: Kiril Zyapkov <kiril.zyapkov@gmail.com>

buildarch=2

pkgname=imx-bootlets-olinuxino
pkgver=10.12.01
pkgrel=5
pkgdesc="Bootlets for the i.MX233 Freescale processor"
arch=(arm)
url="http://freescale.com"
license=('MIT')
makedepends=()
source=("http://download.ossystems.com.br/bsp/freescale/source/imx-bootlets-src-${pkgver}.tar.gz"
        "linux_prep-fix-cmdlines.patch"
        "linux-fix-paths.patch"
        "imx233-olinuxino-maxi.patch")
md5sums=('cf0ab3822dca694b930a051501c1d0e4'
         '27056e5005be16bfa14ae9ee5233974d'
         'a714eb6bcc1ed30b771d98ff2f2c251b'
         'a3ecd391021d32723c34c955a3e2a0f5')

build() {
  cd ${srcdir}/imx-bootlets-src-${pkgver}
  patch -Np1 -i ../linux_prep-fix-cmdlines.patch
  patch -Np1 -i ../linux-fix-paths.patch
  patch -Np1 -i ../imx233-olinuxino-maxi.patch
  
  BOARD=stmp378x_dev make linux_prep boot_prep power_prep
}

package() {
  cd ${srcdir}/imx-bootlets-src-${pkgver}
  mkdir -p ${pkgdir}/opt/imx-bootlets-olinuxino
  install -m 0644 linux.bd ${pkgdir}/opt/imx-bootlets-olinuxino
  install -m 0644 power_prep/power_prep ${pkgdir}/opt/imx-bootlets-olinuxino
  install -m 0644 boot_prep/boot_prep ${pkgdir}/opt/imx-bootlets-olinuxino
  install -m 0644 linux_prep/output-target/linux_prep ${pkgdir}/opt/imx-bootlets-olinuxino
}