PKGBUILDs/extra/gocryptfs/PKGBUILD
2025-02-01 00:26:40 +00:00

39 lines
1.4 KiB
Bash

# Maintainer: Lukas Fleischer <lfleischer@archlinux.org>
# Contributor: Maxim Baz <archlinux at maximbaz dot com>
# Contributor: Peter Reschenhofer <peter.reschenhofer@gmail.com>
# ALARM: Andrea Scarpino <andrea@archlinux.org>
# - disable documentation build
_pkgauthor=rfjakob
pkgname=gocryptfs
pkgver=2.5.1
pkgrel=1
pkgdesc='Encrypted overlay filesystem written in Go.'
arch=('x86_64')
url="https://github.com/${_pkgauthor}/${pkgname}"
license=('MIT')
depends=('glibc' 'openssl' 'fuse3')
makedepends=('go')
source=(
"${pkgname}-${pkgver}.tar.gz::https://github.com/${_pkgauthor}/${pkgname}/releases/download/v${pkgver}/${pkgname}_v${pkgver}_src-deps.tar.gz"
"${pkgname}-${pkgver}.tar.gz.asc::https://github.com/${_pkgauthor}/${pkgname}/releases/download/v${pkgver}/${pkgname}_v${pkgver}_src-deps.tar.gz.asc"
)
sha256sums=('80c3771c9f7e65af9326b107ddb7a30e9c3c7bf8823412b9615b7f77352cdde7'
'SKIP')
validpgpkeys=('FFF3E01444FED7C316A3545A895F5BC123A02740')
build() {
cd "${srcdir}/${pkgname}_v${pkgver}_src-deps"
export CGO_LDFLAGS="$LDFLAGS"
export GOFLAGS="-buildmode=pie -trimpath -mod=vendor"
./build.bash
}
package() {
cd "${srcdir}/${pkgname}_v${pkgver}_src-deps"
install -Dm755 -t "${pkgdir}/usr/bin/" gocryptfs
install -Dm755 -t "${pkgdir}/usr/bin/" gocryptfs-xray/gocryptfs-xray
install -Dm644 -t "${pkgdir}/usr/share/licenses/gocryptfs" LICENSE
}