mirror of
https://github.com/archlinuxarm/PKGBUILDs.git
synced 2024-11-08 22:45:43 +00:00
62 lines
1.5 KiB
Bash
62 lines
1.5 KiB
Bash
# $Id$
|
|
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
|
|
# Maintainer: Jan de Groot <jgc@archlinux.org>
|
|
|
|
# ALARM: Kevin Mihelich
|
|
# - remove valgrind makedepend
|
|
|
|
pkgname=gstreamer
|
|
pkgver=1.12.0
|
|
pkgrel=1
|
|
pkgdesc="GStreamer open-source multimedia framework core library"
|
|
url="https://gstreamer.freedesktop.org/"
|
|
arch=(i686 x86_64)
|
|
license=(LGPL)
|
|
depends=(libxml2 glib2 libunwind libcap libelf)
|
|
makedepends=(intltool pkgconfig gtk-doc gobject-introspection autoconf-archive git
|
|
bash-completion)
|
|
checkdepends=(gmp gsl gtk3)
|
|
_commit=7854a6597868eeb91bca7518ad73adcb3107f56d # tags/1.12.0^0
|
|
install=gstreamer.install
|
|
source=("git+https://anongit.freedesktop.org/git/gstreamer/gstreamer#commit=$_commit"
|
|
"gst-common::git+https://anongit.freedesktop.org/git/gstreamer/common")
|
|
sha256sums=('SKIP'
|
|
'SKIP')
|
|
|
|
pkgver() {
|
|
cd $pkgname
|
|
git describe --tags | sed 's/-/+/g'
|
|
}
|
|
|
|
prepare() {
|
|
cd $pkgname
|
|
|
|
git submodule init
|
|
git config --local submodule.common.url "$srcdir/gst-common"
|
|
git submodule update
|
|
|
|
NOCONFIGURE=1 ./autogen.sh
|
|
}
|
|
|
|
build() {
|
|
cd $pkgname
|
|
./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var --libexecdir=/usr/lib \
|
|
--with-package-name="GStreamer (Arch Linux)" \
|
|
--with-package-origin="http://www.archlinux.org/" \
|
|
--enable-gtk-doc --disable-static
|
|
|
|
# https://bugzilla.gnome.org/show_bug.cgi?id=655517
|
|
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
|
|
|
|
make
|
|
}
|
|
|
|
check() {
|
|
cd $pkgname
|
|
make check
|
|
}
|
|
|
|
package() {
|
|
cd $pkgname
|
|
make DESTDIR="$pkgdir" install
|
|
}
|