mirror of
https://github.com/archlinuxarm/PKGBUILDs.git
synced 2024-11-08 22:45:43 +00:00
94 lines
3.4 KiB
Bash
94 lines
3.4 KiB
Bash
# Maintainer: Alexander F. Rødseth <xyproto@archlinux.org>
|
|
# Contributor: loqs
|
|
# Contributor: Lukas Fleischer <lfleischer@archlinux.org>
|
|
# Contributor: Vesa Kaihlavirta <vesa@archlinux.org>
|
|
# Contributor: Sarah Hay <sarahhay@mb.sympatico.ca>
|
|
# Contributor: Tom Burdick <thomas.burdick@wrightwoodtech.com>
|
|
# Contributor: Ricardo Catalinas Jiménez <jimenezrick@gmail.com>
|
|
|
|
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
|
|
# - configure with --disable-pgo to fix ARM FTBFS
|
|
|
|
pkgbase=erlang
|
|
pkgname=(erlang erlang-unixodbc)
|
|
pkgver=25.0.4
|
|
pkgrel=1
|
|
_docver=25.0
|
|
arch=(x86_64)
|
|
url='https://erlang.org'
|
|
license=(Apache)
|
|
makedepends=(fop git glu java-environment libxslt lksctp-tools mesa perl unixodbc wxwidgets-gtk3)
|
|
options=(staticlibs)
|
|
source=(epmd.conf
|
|
epmd.service
|
|
epmd.socket
|
|
"$url/download/otp_doc_man_$_docver.tar.gz"
|
|
"git+https://github.com/erlang/otp#commit=c028b855ee3f12c835ff3538a90ac5dbc155631b") # tag: OTP-25.0.4
|
|
b2sums=('1675ac9bf948ab19e8b63077d870ccf356fcdbce14de2777f00b3488aa1ce34a5e0a5cdc0428707f744dee5940b12653a44e0ded0554de95ebb31bce4676ff87'
|
|
'1f765318bcd322ce697a48c064ccdb1bd107b4a84e164a87f62678391cb82a9ab17a397d679cf266e037a5a2d91772b85f7a97f9cc5478c0f18118743b30045f'
|
|
'c37706f5f6e2d49100104fb442ebf15edd6ee0a1e8038d0364794cf34fd3f02a61b9ad2706228b3327b85b0cadcd11aac6087e7c98408eae2d307a09191b6553'
|
|
'cb48044163b265fb339b774a854662705d1bdf52cfabf3d4a268538c5e53b984c3d26f05acea2f217a1bf6e838469564cef1a4c591d9af43980e1d8f422c43fd'
|
|
'SKIP')
|
|
|
|
prepare() {
|
|
# adjust how LDFLAGS are handled
|
|
sed -i 's/^LDFLAGS = /LDFLAGS += /g' \
|
|
otp/lib/{odbc/c_src,megaco/src/flex}/Makefile.in
|
|
}
|
|
|
|
build() {
|
|
#export CFLAGS+=' -ffat-lto-objects'
|
|
export WX_GKT_VER='3.2'
|
|
cd otp
|
|
./otp_build autoconf
|
|
./configure \
|
|
--enable-builtin-zlib \
|
|
--enable-smp-support \
|
|
--prefix=/usr \
|
|
--with-odbc \
|
|
--disable-pgo
|
|
make
|
|
}
|
|
|
|
package_erlang() {
|
|
pkgdesc='General-purpose concurrent functional programming language developed by Ericsson'
|
|
depends=(glu ncurses openssl webkit2gtk wxwidgets-gtk3)
|
|
optdepends=('erlang-unixodbc: database support'
|
|
'java-environment: for Java support'
|
|
'lksctp-tools: for SCTP support')
|
|
provides=(erlang-nox)
|
|
conflicts=(erlang-nox)
|
|
|
|
export PATH="$srcdir/bin:$PATH"
|
|
make -C otp DESTDIR="$pkgdir" install
|
|
|
|
# move files that belong to the erlang-unixodbc package
|
|
mkdir -p unixodbc
|
|
mv "$pkgdir/usr/lib/erlang/lib/odbc"* "$srcdir/unixodbc/"
|
|
|
|
# services and configuration
|
|
install -Dm644 epmd.service "$pkgdir/usr/lib/systemd/system/epmd.service"
|
|
install -Dm644 epmd.socket "$pkgdir/usr/lib/systemd/system/epmd.socket"
|
|
install -Dm644 epmd.conf "$pkgdir/etc/conf.d/epmd"
|
|
|
|
# readme and licenses
|
|
install -Dm644 otp/README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
|
|
install -Dm644 otp/LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
|
|
install -Dm644 otp/CONTRIBUTING.md "$pkgdir/usr/share/doc/$pkgname/CONTRIBUTING.md"
|
|
install -Dm644 otp/AUTHORS "$pkgdir/usr/share/doc/$pkgname/AUTHORS"
|
|
|
|
# man pages
|
|
cp -r -v man "$pkgdir/usr/lib/erlang/"
|
|
}
|
|
|
|
package_erlang-unixodbc() {
|
|
pkgdesc='Unixodbc support for Erlang'
|
|
depends=(erlang-nox unixodbc)
|
|
|
|
install -d "$pkgdir/usr/lib/erlang/lib"
|
|
mv unixodbc/* "$pkgdir/usr/lib/erlang/lib/"
|
|
install -Dm644 otp/LICENSE.txt \
|
|
"$pkgdir/usr/share/licenses/$pkgname/LICENCE.txt"
|
|
}
|
|
|
|
# getver: raw.githubusercontent.com/erlang/otp/maint/OTP_VERSION
|