mirror of
https://github.com/archlinuxarm/PKGBUILDs.git
synced 2024-09-19 22:08:32 +00:00
55 lines
1.4 KiB
Bash
55 lines
1.4 KiB
Bash
# $Id$
|
|
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
|
|
# Maintainer: Ionut Biru <ibiru@archlinux.org>
|
|
# Contributor: Michael Kanis <mkanis_at_gmx_dot_de>
|
|
|
|
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
|
|
# - set --enable-compile-warnings=no in configure
|
|
|
|
pkgname=mutter
|
|
pkgver=3.22.1+41+ge8fc090
|
|
pkgrel=1
|
|
pkgdesc="A window manager for GNOME"
|
|
url="https://git.gnome.org/browse/mutter"
|
|
arch=(i686 x86_64)
|
|
license=(GPL)
|
|
depends=(dconf gobject-introspection-runtime gsettings-desktop-schemas
|
|
libcanberra startup-notification zenity libsm gnome-desktop upower
|
|
libxkbcommon-x11 gnome-settings-daemon libgudev libinput)
|
|
makedepends=(intltool gobject-introspection git gnome-common)
|
|
groups=(gnome)
|
|
options=(!emptydirs)
|
|
_commit=e8fc09064afd8b1d50ff401140c412db558a2d62 # gnome-3-22
|
|
source=("git://git.gnome.org/mutter#commit=$_commit")
|
|
sha256sums=('SKIP')
|
|
|
|
pkgver() {
|
|
cd $pkgname
|
|
git describe --tags | sed 's/-/+/g'
|
|
}
|
|
|
|
prepare() {
|
|
cd $pkgname
|
|
NOCONFIGURE=1 ./autogen.sh
|
|
}
|
|
|
|
build() {
|
|
cd $pkgname
|
|
|
|
./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
|
|
--libexecdir=/usr/lib/$pkgname --disable-static \
|
|
--disable-schemas-compile --enable-compile-warnings=no \
|
|
--enable-gtk-doc
|
|
|
|
#https://bugzilla.gnome.org/show_bug.cgi?id=655517
|
|
sed -e 's/ -shared / -Wl,-O1,--as-needed\0/g' \
|
|
-i {.,cogl,clutter}/libtool
|
|
|
|
make
|
|
}
|
|
|
|
package() {
|
|
cd $pkgname
|
|
make DESTDIR="$pkgdir" install
|
|
}
|