mirror of
https://github.com/archlinuxarm/PKGBUILDs.git
synced 2024-12-08 23:03:46 +00:00
82 lines
2.5 KiB
Bash
82 lines
2.5 KiB
Bash
# $Id$
|
|
# Maintainer: Felix Yan <felixonmars@archlinux.org>
|
|
# Contributor Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
|
|
# Contributor: Thomas Dziedzic < gostrc at gmail >
|
|
# Contributor: James Campos <james.r.campos@gmail.com>
|
|
# Contributor: BlackEagle < ike DOT devolder AT gmail DOT com >
|
|
# Contributor: Dongsheng Cai <dongsheng at moodle dot com>
|
|
# Contributor: Masutu Subric <masutu.arch at googlemail dot com>
|
|
# Contributor: TIanyi Cui <tianyicui@gmail.com>
|
|
|
|
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
|
|
# - set config and gyp flags
|
|
|
|
buildarch=28
|
|
|
|
pkgname=nodejs
|
|
pkgver=9.5.0
|
|
pkgrel=1
|
|
pkgdesc='Evented I/O for V8 javascript'
|
|
arch=('x86_64')
|
|
url='http://nodejs.org/'
|
|
license=('MIT')
|
|
depends=('openssl-1.0' 'zlib' 'icu' 'libuv' 'http-parser' 'c-ares') # 'v8')
|
|
makedepends=('python2' 'procps-ng')
|
|
optdepends=('npm: nodejs package manager')
|
|
source=("nodejs-$pkgver.tar.gz::https://github.com/nodejs/node/archive/v$pkgver.tar.gz")
|
|
sha512sums=('b59e5e8bdcd69f6c0cfa6cc92b8cce6933fb6476ea607735cc53f526b1dec569c21ea98c75dc409a80fd538b48eb5bd069e2f2b3c0a74416108b4455b644421c')
|
|
|
|
prepare() {
|
|
cd node-$pkgver
|
|
|
|
msg 'Fixing for python2 name'
|
|
find -type f -exec sed \
|
|
-e 's_^#!/usr/bin/env python$_&2_' \
|
|
-e 's_^\(#!/usr/bin/python2\).[45]$_\1_' \
|
|
-e 's_^#!/usr/bin/python$_&2_' \
|
|
-e 's_^\( *exec \+\)python\( \+.*\)$_\1python2\2_'\
|
|
-e 's_^\(.*\)python\( \+-c \+.*\)$_\1python2\2_'\
|
|
-e "s_'python'_'python2'_" -i {} \;
|
|
find test/ -type f -exec sed 's_python _python2 _' -i {} \;
|
|
}
|
|
|
|
build() {
|
|
cd node-$pkgver
|
|
|
|
export PKG_CONFIG_PATH=/usr/lib/openssl-1.0/pkgconfig
|
|
export PYTHON=python2
|
|
|
|
[[ "$CARCH" == "armv6h" ]] && export CONFIG="--with-arm-float-abi=hard --with-arm-fpu=vfp" && export GYPFLAGS="-Darm_thumb -Darm_float_abi=hard -Darm_version=6 -Darm_fpu=vfpv2"
|
|
[[ "$CARCH" == "armv7h" ]] && export CONFIG="--with-arm-float-abi=hard --with-arm-fpu=vfpv3-d16" && export GYPFLAGS="-Darm_thumb -Darm_float_abi=hard -Darm_version=7 -Darm_fpu=vfpv3-d16"
|
|
|
|
./configure \
|
|
--prefix=/usr \
|
|
--with-intl=system-icu \
|
|
--without-npm \
|
|
--shared-openssl \
|
|
--shared-zlib \
|
|
--shared-libuv \
|
|
--shared-http-parser \
|
|
--shared-cares \
|
|
${CONFIG}
|
|
# --shared-v8
|
|
|
|
make
|
|
}
|
|
|
|
check() {
|
|
cd node-$pkgver
|
|
# Expected failure: https://github.com/nodejs/node/issues/11627
|
|
make test || warning "Tests failed"
|
|
}
|
|
|
|
package() {
|
|
cd node-$pkgver
|
|
|
|
make DESTDIR="$pkgdir" install
|
|
|
|
install -D -m644 LICENSE \
|
|
"$pkgdir"/usr/share/licenses/nodejs/LICENSE
|
|
}
|
|
|
|
# vim:set ts=2 sw=2 et:
|