archlinuxarm/PKGBUILDs
1
0
Fork 0
mirror of https://github.com/archlinuxarm/PKGBUILDs.git synced 2024-11-08 22:45:43 +00:00
Code Issues Projects Releases Packages Wiki Activity Actions
PKGBUILDs/extra/vlc/PKGBUILD
Kevin Mihelich fc9871aed7 extra/vlc to 3.0.3-4
2018-08-16 12:23:03 +00:00

239 lines
9.5 KiB
Bash
Raw Blame History

# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Contributor: Giovanni Scafora <giovanni@archlinux.org>
# Contributor: Sarah Hay <sarahhay@mb.sympatico.ca>
# Contributor: Martin Sandsmark <martin.sandsmark@kde.org>
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
# - enable gles2
pkgname=vlc
pkgver=3.0.3
pkgrel=4
pkgdesc='Multi-platform MPEG, VCD/DVD, and DivX player'
url='https://www.videolan.org/vlc/'
arch=('x86_64')
license=('LGPL2.1' 'GPL2')
depends=('a52dec' 'libdvbpsi' 'libxpm' 'libdca' 'libproxy' 'lua'
'libmatroska' 'taglib' 'libmpcdec' 'ffmpeg' 'faad2' 'libupnp' 'libmad'
'libmpeg2' 'xcb-util-keysyms' 'libtar' 'libxinerama' 'libsecret'
'libarchive' 'qt5-base' 'qt5-x11extras' 'qt5-svg' 'freetype2'
'fribidi' 'harfbuzz' 'fontconfig' 'libxml2' 'gnutls' 'libplacebo'
'wayland-protocols')
makedepends=('gst-plugins-base-libs' 'live-media' 'libnotify' 'libbluray'
'flac' 'kdelibs' 'libdc1394' 'libavc1394' 'libcaca' 'gtk3'
'librsvg' 'libgme' 'xosd' 'twolame' 'aalib' 'avahi' 'libsystemd'
'libmtp' 'libupnp' 'libmicrodns' 'libdvdcss' 'smbclient'
'vcdimager' 'libssh2' 'mesa' 'protobuf' 'libnfs' 'mpg123'
'libdvdread' 'libdvdnav' 'libogg' 'libshout' 'libmodplug' 'libvpx'
'libvorbis' 'speex' 'opus' 'libtheora' 'libpng' 'libjpeg-turbo'
'libx265.so' 'libx264.so' 'zvbi' 'libass' 'libkate' 'libtiger'
'sdl_image' 'libpulse' 'alsa-lib' 'jack' 'libsamplerate' 'libsoxr'
'lirc' 'libgoom2' 'projectm' 'chromaprint')
optdepends=('avahi: service discovery using bonjour protocol'
'gst-plugins-base-libs: for libgst plugins'
'libdvdcss: decoding encrypted DVDs'
'libavc1394: devices using the 1394ta AV/C'
'libdc1394: IEEE 1394 access plugin'
'kdelibs: KDE Solid hardware integration'
'kwallet: kwallet keystore'
'libva-vdpau-driver: vdpau backend nvidia'
'libva-intel-driver: video backend intel'
'libbluray: Blu-Ray video input'
'flac: Free Lossless Audio Codec plugin'
'twolame: TwoLAME mpeg2 encoder plugin'
'libgme: Game Music Emu plugin'
'vcdimager: navigate VCD with libvcdinfo'
'libmtp: MTP devices discovery'
'libsystemd: udev services discovery'
'smbclient: SMB access plugin'
'libcdio: audio CD playback'
'ttf-freefont: subtitle font '
'ttf-dejavu: subtitle font'
'libssh2: sftp access'
'libnfs: NFS access'
'mpg123: mpg123 codec'
'protobuf: chromecast streaming'
'libmicrodns: mDNS services discovery (chromecast etc)'
'lua-socket: http interface'
'live-media: RTSP input'
'libdvdread: DVD input module'
'libdvdnav: DVD with navigation input module'
'libogg: Ogg and OggSpots codec'
'libshout: shoutcast/icecast output plugin'
'libmodplug: MOD output plugin'
'libvpx: VP8 and VP9 codec'
'libvorbis: Vorbis decoder/encoder'
'speex: Speex codec'
'opus: opus codec'
'libtheora: theora codec'
'libpng: PNG support'
'libjpeg-turbo: JPEG support'
'librsvg: SVG plugin'
'x264: H264 encoding'
'x265: HEVC/H.265 encoder'
'zvbi: VBI/Teletext decoding'
'libass: Subtitle support'
'libkate: Kate codec'
'libtiger: Tiger rendering for Kate streams'
'sdl_image: SDL image support'
'aalib: ASCII art video output'
'libcaca: colored ASCII art video output'
'libpulse: PulseAudio audio output'
'alsa-lib: ALSA audio output'
'jack: jack audio server'
'libsamplerate: audio Resampler'
'libsoxr: SoX audio Resampler'
'chromaprint: Chromaprint audio fingerprinter'
'lirc: lirc control'
'libgoom2: Goom visualization'
'projectm: ProjectM visualisation'
'ncurses: ncurses interface'
'libnotify: notification plugin'
'gtk3: notification plugin')
conflicts=('vlc-plugin')
replaces=('vlc-plugin')
options=('!emptydirs')
source=(https://download.videolan.org/${pkgname}/${pkgver}/${pkgname}-${pkgver}-1.tar.xz{,.asc}
update-vlc-plugin-cache.hook
aom-remove-unsupported-pixel-formats.patch
lua53_compat.patch
vlc-qt5.11.patch
vlc-x264-155.patch)
sha512sums=('d1979f6149821cf91d7b40b18d83d399b9021966b60589615638423a4e2c3ff86fdbbe9c0d92c85bfdd90f03991256ccee95d7a33ae96326177bb2bfe85e7a0f'
'SKIP'
'80357bae69e32b353d3784932d854e294906798e14faffb87c3383c3b6f6bdc57cbabb9c6e3f3c1adf0f8ddbb24153e72104c963cf1934970c2983c96daef9df'
'5757a6f35e106883072c31d137fd247c65a544f730cf736ca2e81a31357305b5c002b52349337d8e1667fbe68628bc253ec69eee727f268aee7902a5bef82dce'
'33cda373aa1fb3ee19a78748e2687f2b93c8662c9fda62ecd122a2e649df8edaceb54dda3991bc38c80737945a143a9e65baa2743a483bb737bb94cd590dc25f'
'66aad0ec32d1a96f65566b04eb9c0b4574824e281940fe5c0de54ac5f92189693a9f2576203d2c8562d7174ec5315cbbd683d93c481d16119d3038e30a58cbf5'
'47b844c7ada22042a0aab67d485ee68fda4847400dedd0f5662eb3738c1e45a06b50a6a045f3af1f07625ebd6f021bd43acaa9a8e63720e3b1207ad0d23bb36f')
validpgpkeys=('65F7C6B4206BD057A7EB73787180713BE58D1ADC') # VideoLAN Release Signing Key
prepare() {
cd ${pkgname}-${pkgver}
sed -e 's:truetype/ttf-dejavu:TTF:g' -i modules/visualization/projectm.cpp
sed -e 's|-Werror-implicit-function-declaration||g' -i configure
sed 's|whoami|echo builduser|g' -i configure
sed 's|hostname -f|echo arch|g' -i configure
patch -Np1 < "${srcdir}/aom-remove-unsupported-pixel-formats.patch"
patch -Np1 < "${srcdir}/lua53_compat.patch"
patch -Np1 < "${srcdir}/vlc-qt5.11.patch"
patch -Np1 < "${srcdir}/vlc-x264-155.patch"
}
build() {
cd ${pkgname}-${pkgver}
export CFLAGS+=" -I/usr/include/samba-4.0"
export CPPFLAGS+=" -I/usr/include/samba-4.0"
export CXXFLAGS+=" -std=c++11"
export LUAC=/usr/bin/luac
export LUA_LIBS="$(pkg-config --libs lua)"
export RCC=/usr/bin/rcc-qt5
./configure --prefix=/usr \
--sysconfdir=/etc \
--disable-rpath \
--enable-nls \
--enable-archive \
--enable-live555 \
--enable-dc1394 \
--enable-dv1394 \
--enable-dvdread \
--enable-dvdnav \
--enable-bluray \
--disable-opencv \
--enable-smbclient \
--enable-sftp \
--enable-nfs \
--enable-realrtsp \
--enable-dvbpsi \
--enable-gme \
--enable-ogg \
--enable-shout \
--enable-matroska \
--enable-mod \
--enable-mpc \
--enable-mad \
--enable-mpg123 \
--enable-gst-decode \
--enable-avcodec \
--enable-libva \
--enable-avformat \
--enable-postproc \
--enable-faad \
--enable-vpx \
--enable-twolame \
--disable-fdkaac \
--enable-a52 \
--enable-dca \
--enable-flac \
--enable-libmpeg2 \
--enable-vorbis \
--enable-speex \
--enable-opus \
--enable-oggspots \
--disable-schroedinger \
--enable-png \
--enable-jpeg \
--enable-x264 \
--enable-x265 \
--enable-zvbi \
--enable-libass \
--enable-kate \
--enable-tiger \
--enable-vdpau \
--enable-wayland \
--enable-sdl-image \
--enable-freetype \
--enable-fribidi \
--enable-harfbuzz \
--enable-fontconfig \
--enable-svg \
--enable-svgdec \
--enable-aa \
--enable-caca \
--enable-pulse \
--enable-alsa \
--enable-jack \
--enable-samplerate \
--enable-soxr \
--enable-chromaprint \
--enable-chromecast \
--enable-qt \
--enable-skins2 \
--enable-libtar \
--enable-ncurses \
--enable-lirc \
--enable-goom \
--enable-projectm \
--enable-avahi \
--enable-mtp \
--enable-upnp \
--enable-microdns \
--enable-libxml2 \
--disable-libgcrypt \
--enable-gnutls \
--enable-taglib \
--enable-secret \
--enable-kwallet \
--disable-update-check \
--enable-notify \
--enable-libplacebo \
--enable-vlc \
--enable-gles2
make
}
package() {
cd "${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
for res in 16 32 48 128 256; do
install -Dm 644 "${srcdir}/vlc-${pkgver}/share/icons/${res}x${res}/vlc.png" \
"${pkgdir}/usr/share/icons/hicolor/${res}x${res}/apps/vlc.png"
done
install -Dm 644 "${srcdir}/update-vlc-plugin-cache.hook" -t "${pkgdir}/usr/share/libalpm/hooks"
}
# vim: ts=2 sw=2 et:
Reference in a new issue View git blame Copy permalink