mirror of
https://github.com/archlinuxarm/PKGBUILDs.git
synced 2024-09-19 22:08:32 +00:00
66 lines
2 KiB
Bash
66 lines
2 KiB
Bash
# $Id$
|
|
# Maintainer: Felix Yan <felixonmars@archlinux.org>
|
|
# Contributor: Andrea Scarpino <andrea@archlinux.org>
|
|
|
|
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
|
|
# - patch for chromium GN
|
|
|
|
buildarch=12
|
|
highmem=1
|
|
|
|
pkgname=qt5-webengine
|
|
_qtver=5.9.2
|
|
pkgver=${_qtver/-/}
|
|
pkgrel=1
|
|
arch=('i686' 'x86_64')
|
|
url='http://qt-project.org/'
|
|
license=('LGPL3' 'LGPL2.1' 'BSD')
|
|
pkgdesc='Provides support for web applications using the Chromium browser project'
|
|
depends=('qt5-webchannel' 'qt5-location' 'libxcomposite' 'libxrandr' 'pciutils' 'libxss' 'libvpx'
|
|
'libevent' 'libsrtp' 'snappy' 'nss' 'protobuf' 'libxslt' 'libxdamage' 'minizip' 'ffmpeg')
|
|
# namcap note: libxdamage is needed for nvidia users
|
|
makedepends=('python2' 'git' 'gperf' 'jsoncpp' 'ninja')
|
|
groups=('qt' 'qt5')
|
|
_pkgfqn="${pkgname/5-/}-opensource-src-${_qtver}"
|
|
source=("http://download.qt.io/official_releases/qt/${pkgver%.*}/${_qtver}/submodules/${_pkgfqn}.tar.xz"
|
|
harmony-fix.diff
|
|
'0001-ARM-toolchain-fixes.patch')
|
|
sha256sums=('cab069e4589f806640bebe4077c70e5cd5ffeb146c6e8caca6c4454fc0c4a108'
|
|
'2c309c0f6978e6a399422319b5034b01881d5526cf48b2ee5fcc7f418029a344'
|
|
'8202b09a1caa82538a2eacd79b62b61d8661c65cdfb275560d231aa31a362b12')
|
|
|
|
prepare() {
|
|
mkdir -p build
|
|
|
|
# Hack to force using python2
|
|
mkdir -p bin
|
|
ln -s /usr/bin/python2 bin/python
|
|
|
|
cd ${_pkgfqn}
|
|
|
|
# FreeType 2.8.1
|
|
patch -Np1 -i ../harmony-fix.diff
|
|
|
|
cd src/3rdparty
|
|
patch -p1 -i ${srcdir}/0001-ARM-toolchain-fixes.patch
|
|
}
|
|
|
|
build() {
|
|
cd build
|
|
|
|
export PATH="$srcdir/bin:$PATH"
|
|
qmake CONFIG+="proprietary-codecs" WEBENGINE_CONFIG+="use_proprietary_codecs use_system_icu" ../${_pkgfqn}
|
|
make
|
|
}
|
|
|
|
package() {
|
|
cd build
|
|
make INSTALL_ROOT="$pkgdir" install
|
|
|
|
# Drop QMAKE_PRL_BUILD_DIR because reference the build dir
|
|
find "$pkgdir/usr/lib" -type f -name '*.prl' \
|
|
-exec sed -i -e '/^QMAKE_PRL_BUILD_DIR/d' {} \;
|
|
|
|
install -Dm644 "$srcdir"/${_pkgfqn}/src/3rdparty/chromium/LICENSE "$pkgdir"/usr/share/licenses/${pkgname}/LICENSE.chromium
|
|
}
|