mirror of
https://github.com/archlinuxarm/PKGBUILDs.git
synced 2024-11-08 22:45:43 +00:00
57 lines
2.2 KiB
Bash
57 lines
2.2 KiB
Bash
# Maintainer: Andreas Radke <andyrtr@archlinux.org>
|
|
# Contributor: Art Gramlich <art@gramlich-net.com>
|
|
|
|
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
|
|
# - patch to fix icudata library linking on ARM
|
|
# - remove check for clang in configure - picks up distcc
|
|
|
|
pkgname=icu
|
|
pkgver=68.2
|
|
pkgrel=1
|
|
pkgdesc="International Components for Unicode library"
|
|
arch=(x86_64)
|
|
url="http://site.icu-project.org/home"
|
|
license=('custom:icu')
|
|
depends=('gcc-libs' 'sh')
|
|
makedepends=('python')
|
|
provides=(libicu{data,i18n,io,test,tu,uc}.so)
|
|
source=(https://github.com/unicode-org/icu/releases/download/release-${pkgver//./-}/${pkgname}4c-${pkgver//./_}-src.tgz{,.asc}
|
|
icudata-stdlibs.patch)
|
|
# https://github.com/unicode-org/icu/releases/download/release-68-1/SHASUM512.txt
|
|
sha512sums=('24f3b7981667b37df58118f56ae76a09b719358c1efa8d6f044d28ef8df1c722a894957acadfb3c37aee39ac845893924fc3370d6bbe09875aec8d937059f84b'
|
|
'SKIP'
|
|
'8f13898c2b2d69ef516ee0831a73e5865676795716e7becac4457e208642bfdffb42f2a9280e99dcc10303ad721f5dc2e10ef83c633bd723044e98cc72c6bc7b')
|
|
validpgpkeys=('BA90283A60D67BA0DD910A893932080F4FB419E3') # "Steven R. Loomis (filfla-signing) <srloomis@us.ibm.com>"
|
|
validpgpkeys+=('9731166CD8E23A83BEE7C6D3ACA5DBE1FD8FABF1') # "Steven R. Loomis (ICU Project) <srl@icu-project.org>"
|
|
validpgpkeys+=('FFA9129A180D765B7A5BEA1C9B432B27D1BA20D7') # "Fredrik Roubert <fredrik@roubert.name>"
|
|
validpgpkeys+=('E4098B78AFC94394F3F49AA903996C7C83F12F11') # "keybase.io/srl295 <srl295@keybase.io>"
|
|
validpgpkeys+=('4569BBC09DA846FC91CBD21CE1BBA44593CF2AE0') # "Steven R. Loomis (codesign-qormi) <srloomis@us.ibm.com>"
|
|
validpgpkeys+=('0E51E7F06EF719FBD072782A5F56E5AFA63CCD33') #"Craig Cornelius (For use with ICU releases) <ccornelius@google.com>"
|
|
|
|
prepare() {
|
|
cd icu/source
|
|
patch -p2 -i ${srcdir}/icudata-stdlibs.patch
|
|
sed -r -i 's/(for ac_prog in )clang(\+\+)? /\1/g' configure
|
|
}
|
|
|
|
build() {
|
|
cd icu/source
|
|
./configure --prefix=/usr \
|
|
--sysconfdir=/etc \
|
|
--mandir=/usr/share/man \
|
|
--sbindir=/usr/bin
|
|
make
|
|
}
|
|
|
|
check() {
|
|
cd icu/source
|
|
make -k check
|
|
}
|
|
|
|
package() {
|
|
cd icu/source
|
|
make -j1 DESTDIR="${pkgdir}" install
|
|
|
|
# Install license
|
|
install -Dm644 "${srcdir}"/icu/LICENSE "${pkgdir}"/usr/share/licenses/icu/LICENSE
|
|
}
|