mirror of
https://github.com/archlinuxarm/PKGBUILDs.git
synced 2024-09-19 22:08:32 +00:00
84 lines
3 KiB
Bash
84 lines
3 KiB
Bash
# $Id$
|
|
# Maintainer : Ionut Biru <ibiru@archlinux.org>
|
|
# Contributor: Alexander Baldeck <alexander@archlinux.org>
|
|
# Contributor: Dale Blount <dale@archlinux.org>
|
|
# Contributor: Anders Bostrom <anders.bostrom@home.se>
|
|
|
|
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
|
|
# - mozconfig changes for ARM
|
|
# - patch to remove NEON/SIMD checks from configure
|
|
# - memory saving LDFLAGS
|
|
# - enable calendar in mozconfig
|
|
|
|
buildarch=20
|
|
|
|
pkgname=thunderbird
|
|
pkgver=31.2.0
|
|
pkgrel=1
|
|
pkgdesc="Standalone Mail/News reader"
|
|
arch=('i686' 'x86_64')
|
|
license=('MPL' 'GPL')
|
|
url="http://www.mozilla.org/thunderbird/"
|
|
depends=('alsa-lib' 'dbus-glib' 'desktop-file-utils' 'gtk2' 'hicolor-icon-theme' 'hunspell' 'libevent' 'libvpx' 'libxt' 'mime-types' 'mozilla-common' 'nss' 'sqlite' 'startup-notification')
|
|
makedepends=('unzip' 'zip' 'python2' 'wireless_tools' 'yasm' 'mesa' 'libpulse')
|
|
optdepends=('libcanberra: for sound support')
|
|
install=thunderbird.install
|
|
source=(https://ftp.mozilla.org/pub/mozilla.org/thunderbird/releases/$pkgver/source/thunderbird-$pkgver.source.tar.bz2{,.asc}
|
|
mozconfig
|
|
thunderbird.desktop
|
|
thunderbird-install-dir.patch
|
|
vendor.js
|
|
no-neon.patch)
|
|
options=(!emptydirs)
|
|
sha256sums=('48130bbd9102303167aa832ea80970201777ee65b91fbab515332527850749b4'
|
|
'SKIP'
|
|
'a997200050983ae0a4c8d5823eaf5f6844f50610d7fb252eebda2d2c59fc8bc3'
|
|
'd506b771e765e09e2e039b975e25befade8eec97e8950813a32463604955ab4e'
|
|
'9049ab3f9600a1592a54c41a166c76e046c393e1cfe7c4e769155b7317d197ee'
|
|
'e4ea8e6788163d9f8db8f1f40023db3ea0a1358f9a4510169f2d4c4fe6a887ed'
|
|
'014a2f160c2f21b854d21c0ae5cd6ad7493586f03cae4399960f75570ee2ce92')
|
|
|
|
prepare() {
|
|
cd comm-esr31
|
|
patch -Np1 -i "$srcdir/thunderbird-install-dir.patch"
|
|
|
|
patch -Np0 -i ../no-neon.patch
|
|
|
|
cp "$srcdir/mozconfig" .mozconfig
|
|
|
|
# configure script misdetects the preprocessor without an optimization level
|
|
# https://bugs.archlinux.org/task/34644
|
|
sed -i '/ac_cpp=/s/$CPPFLAGS/& -O2/' mozilla/configure
|
|
}
|
|
|
|
build() {
|
|
cd comm-esr31
|
|
|
|
export LDFLAGS="$LDFLAGS -Wl,-rpath,/usr/lib/thunderbird -Wl,--no-keep-memory -Wl,--reduce-memory-overheads"
|
|
export PYTHON="/usr/bin/python2"
|
|
|
|
make -j1 -f client.mk build MOZ_MAKE_FLAGS="$MAKEFLAGS"
|
|
}
|
|
|
|
package() {
|
|
cd comm-esr31
|
|
make -j1 -f client.mk DESTDIR="$pkgdir" install
|
|
|
|
install -Dm644 "$srcdir"/vendor.js "$pkgdir/usr/lib/thunderbird/defaults/preferences/vendor.js"
|
|
|
|
for i in 16x16 22x22 24x24 32x32 48x48 256x256; do
|
|
install -Dm644 other-licenses/branding/thunderbird/mailicon${i/x*/}.png \
|
|
"$pkgdir/usr/share/icons/hicolor/$i/apps/thunderbird.png"
|
|
done
|
|
|
|
install -Dm644 "$srcdir/thunderbird.desktop" \
|
|
"$pkgdir/usr/share/applications/thunderbird.desktop"
|
|
|
|
rm -rf "$pkgdir"/usr/lib/thunderbird/{dictionaries,hyphenation}
|
|
ln -sf /usr/share/hunspell "$pkgdir/usr/lib/thunderbird/dictionaries"
|
|
ln -sf /usr/share/hyphen "$pkgdir/usr/lib/thunderbird/hyphenation"
|
|
|
|
# We don't want the development stuff
|
|
rm -r "$pkgdir"/usr/{include,lib/thunderbird-devel-*,share/idl}
|
|
}
|