mirror of
https://github.com/archlinuxarm/PKGBUILDs.git
synced 2024-09-19 22:08:32 +00:00
52 lines
1.3 KiB
Bash
52 lines
1.3 KiB
Bash
# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
|
|
# Maintainer: Jan de Groot <jgc@archlinux.org>
|
|
# Contributor: Brice Carpentier <brice@daknet.org>
|
|
|
|
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
|
|
# - drop valgrind makedepend
|
|
|
|
pkgname=cairo
|
|
pkgver=1.17.4
|
|
pkgrel=3
|
|
pkgdesc="2D graphics library with support for multiple output devices"
|
|
url="https://cairographics.org/"
|
|
arch=(x86_64)
|
|
license=(LGPL MPL)
|
|
depends=(lzo zlib libpng fontconfig freetype2 libx11 libxext libxrender libxcb
|
|
glib2 pixman)
|
|
makedepends=(git meson)
|
|
_commit=156cd3eaaebfd8635517c2baf61fcf3627ff7ec2 # tags/1.17.4^0
|
|
source=("git+https://gitlab.freedesktop.org/cairo/cairo.git#commit=$_commit"
|
|
xlib-xcb.diff)
|
|
sha256sums=('SKIP'
|
|
'70cd3783381bf73ea7fccd5c2db43956b10865a9c54d5edd251dbcdb9b595a43')
|
|
|
|
pkgver() {
|
|
cd cairo
|
|
git describe --tags | sed 's/-/+/g'
|
|
}
|
|
|
|
prepare() {
|
|
cd cairo
|
|
|
|
# Fix library versioning
|
|
# https://bugs.archlinux.org/task/69012
|
|
git cherry-pick -n e9ccb1d8d095482e4139da658e679d5aad56b184
|
|
|
|
# Disable XCB backend for Xlib surfaces
|
|
# https://bugs.archlinux.org/task/68839
|
|
git apply -3 ../xlib-xcb.diff
|
|
}
|
|
|
|
build() {
|
|
arch-meson cairo build \
|
|
-D spectre=disabled \
|
|
-D tee=enabled \
|
|
-D tests=disabled
|
|
meson compile -C build
|
|
}
|
|
|
|
package() {
|
|
DESTDIR="$pkgdir" meson install -C build
|
|
}
|