mirror of
https://github.com/archlinuxarm/PKGBUILDs.git
synced 2024-09-19 22:08:32 +00:00
140 lines
4.4 KiB
Bash
140 lines
4.4 KiB
Bash
# vim:set ts=2 sw=2 et:
|
|
# $Id$
|
|
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
|
|
# Maintainer: BlackIkeEagle < ike DOT devolder AT gmail DOT com >
|
|
# Contributor: Brad Fanella <bradfanella@archlinux.us>
|
|
# Contributor: [vEX] <niechift.dot.vex.at.gmail.dot.com>
|
|
# Contributor: Zeqadious <zeqadious.at.gmail.dot.com>
|
|
# Contributor: BlackIkeEagle < ike DOT devolder AT gmail DOT com >
|
|
# Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
|
|
# Contributor: Maxime Gauduin <alucryd@gmail.com>
|
|
|
|
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
|
|
# - remove libvdpau dependency
|
|
# - --disable-vaapi
|
|
|
|
buildarch=4
|
|
|
|
pkgbase=kodi
|
|
pkgname=('kodi' 'kodi-eventclients')
|
|
pkgver=15.2
|
|
_codename=Isengard
|
|
pkgrel=3
|
|
arch=('i686' 'x86_64')
|
|
url="http://kodi.tv"
|
|
license=('GPL2')
|
|
makedepends=(
|
|
'afpfs-ng' 'bluez-libs' 'boost' 'cmake' 'curl' 'cwiid' 'doxygen' 'git' 'glew'
|
|
'gperf' 'hicolor-icon-theme' 'jasper' 'java-runtime' 'libaacs' 'libass'
|
|
'libbluray' 'libcdio' 'libcec' 'libgl' 'libmariadbclient' 'libmicrohttpd'
|
|
'libmodplug' 'libmpeg2' 'libnfs' 'libplist' 'libpulse' 'libssh' 'libva'
|
|
'libxrandr' 'libxslt' 'lzo' 'mesa' 'nasm' 'nss-mdns'
|
|
'python2-pillow' 'python2-pybluez' 'python2-simplejson' 'rtmpdump' 'sdl2'
|
|
'sdl_image' 'shairplay' 'smbclient' 'swig' 'taglib' 'tinyxml' 'unzip' 'upower'
|
|
'yajl' 'zip'
|
|
)
|
|
source=(
|
|
"$pkgname-$pkgver-$_codename.tar.gz::https://github.com/xbmc/xbmc/archive/$pkgver-$_codename.tar.gz"
|
|
'prevent-taglib-from-crashing-kodi.patch' # can stay in even with new taglib release
|
|
)
|
|
sha256sums=('dd8aeb942e6de5d1488e243e1346cff3f6597e21b5131a3ba72ff5cc82037110'
|
|
'c588153311adbccd7484cc7381f5852b4199301fe04d917279c0a2535891159f')
|
|
|
|
prepare() {
|
|
cd "$srcdir/xbmc-$pkgver-$_codename"
|
|
|
|
find -type f -name *.py -exec sed 's|^#!.*python$|#!/usr/bin/python2|' -i "{}" +
|
|
sed 's|^#!.*python$|#!/usr/bin/python2|' -i tools/depends/native/rpl-native/rpl
|
|
sed 's/python/python2/' -i tools/Linux/kodi.sh.in
|
|
sed 's/shell python/shell python2/' -i tools/EventClients/Makefile.in
|
|
|
|
# patches
|
|
patch -p0 -i "$srcdir/prevent-taglib-from-crashing-kodi.patch"
|
|
}
|
|
|
|
build() {
|
|
cd "$srcdir/xbmc-$pkgver-$_codename"
|
|
|
|
# Bootstrapping
|
|
MAKEFLAGS=-j1 ./bootstrap
|
|
|
|
#./configure --help
|
|
#return 1
|
|
|
|
# Configuring XBMC
|
|
export PYTHON_VERSION=2 # external python v2
|
|
./configure --prefix=/usr --exec-prefix=/usr \
|
|
--disable-debug \
|
|
--enable-optimizations \
|
|
--enable-libbluray \
|
|
--enable-shared-libraries \
|
|
--with-lirc-device=/run/lirc/lircd \
|
|
--disable-vaapi \
|
|
ac_cv_type__Bool=yes
|
|
|
|
# Now (finally) build
|
|
make
|
|
}
|
|
|
|
package_kodi() {
|
|
pkgdesc="A software media player and entertainment hub for digital media"
|
|
|
|
# depends expected for kodi plugins:
|
|
# 'python2-pillow' 'python2-pybluez' 'python2-simplejson'
|
|
# depends expeced in FEH.py
|
|
# 'mesa-demos' 'xorg-xdpyinfo'
|
|
depends=(
|
|
'python2-pillow' 'python2-pybluez' 'python2-simplejson'
|
|
'mesa-demos' 'xorg-xdpyinfo'
|
|
'bluez-libs' 'fribidi' 'glew' 'hicolor-icon-theme' 'libass' 'libcdio'
|
|
'libjpeg-turbo' 'libmariadbclient' 'libmicrohttpd' 'libpulse' 'libssh'
|
|
'libva' 'libxrandr' 'libxslt' 'lzo' 'sdl2' 'smbclient' 'taglib' 'tinyxml'
|
|
'yajl'
|
|
)
|
|
optdepends=(
|
|
'afpfs-ng: Apple shares support'
|
|
'bluez: Blutooth support'
|
|
'libnfs: NFS shares support'
|
|
'libplist: AirPlay support'
|
|
'libcec: Pulse-Eight USB-CEC adapter support'
|
|
'lirc: Remote controller support'
|
|
'pulseaudio: PulseAudio support'
|
|
'shairplay: AirPlay support'
|
|
'udisks: Automount external drives'
|
|
'unrar: Archives support'
|
|
'unzip: Archives support'
|
|
'upower: Display battery level'
|
|
'lsb-release: log distro information in crashlog'
|
|
)
|
|
install="kodi.install"
|
|
provides=('xbmc')
|
|
conflicts=('xbmc')
|
|
replaces=('xbmc')
|
|
|
|
cd "$srcdir/xbmc-$pkgver-$_codename"
|
|
# Running make install
|
|
make DESTDIR="$pkgdir" install
|
|
|
|
# We will no longer support the xbmc name
|
|
rm "$pkgdir/usr/share/xsessions/xbmc.desktop"
|
|
rm "$pkgdir/usr/bin/"xbmc{,-standalone}
|
|
# we will leave /usr/{include,lib,share}/xbmc for now
|
|
|
|
# Licenses
|
|
install -dm755 ${pkgdir}/usr/share/licenses/${pkgname}
|
|
for licensef in LICENSE.GPL copying.txt; do
|
|
mv ${pkgdir}/usr/share/doc/kodi/${licensef} \
|
|
${pkgdir}/usr/share/licenses/${pkgname}
|
|
done
|
|
}
|
|
|
|
package_kodi-eventclients() {
|
|
pkgdesc="Kodi Event Clients"
|
|
|
|
depends=('cwiid')
|
|
|
|
cd "$srcdir/xbmc-$pkgver-$_codename"
|
|
|
|
make DESTDIR="$pkgdir" eventclients WII_EXTRA_OPTS=-DCWIID_OLD
|
|
}
|