mirror of
https://github.com/archlinuxarm/PKGBUILDs.git
synced 2024-09-19 22:08:32 +00:00
66 lines
2.1 KiB
Bash
66 lines
2.1 KiB
Bash
# $Id$
|
|
# Contributor: Eric Bélanger <eric@archlinux.org>
|
|
|
|
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
|
|
# - do not use LLINT assembly for v5/v6
|
|
# - remove Atomics.cpp from build for v5/v6 - https://bugs.webkit.org/show_bug.cgi?id=161900
|
|
|
|
highmem=1
|
|
|
|
pkgname=webkit2gtk
|
|
pkgver=2.18.3
|
|
pkgrel=2
|
|
pkgdesc="GTK+ Web content engine library"
|
|
arch=(x86_64)
|
|
url="https://webkitgtk.org/"
|
|
license=(custom)
|
|
depends=(libxt libxslt enchant geoclue2 gst-plugins-base-libs gst-plugins-bad
|
|
libsecret libwebp harfbuzz-icu gtk3 libnotify hyphen)
|
|
makedepends=(gtk2 gperf gobject-introspection ruby gtk-doc cmake python python2 ninja)
|
|
optdepends=('gtk2: Netscape plugin support'
|
|
'gst-plugins-base: free media decoding'
|
|
'gst-plugins-good: media decoding'
|
|
'gst-libav: nonfree media decoding')
|
|
source=(https://webkitgtk.org/releases/webkitgtk-${pkgver}.tar.xz{,.asc}
|
|
remove_atomics.patch)
|
|
sha256sums=('e15420e1616a6f70f321541d467af5ca285bff66b1e0fa68a01df3ccf1b18f9e'
|
|
'SKIP'
|
|
'410449817b1b181737538be10d96d6d8aec134285f6288e80c96fbfdd5d19519')
|
|
validpgpkeys=('D7FCF61CF9A2DEAB31D81BD3F3D322D0EC4582C3')
|
|
|
|
prepare() {
|
|
mkdir build
|
|
cd webkitgtk-$pkgver
|
|
|
|
sed -i '1s/python$/&2/' Tools/gtk/generate-gtkdoc
|
|
rm -r Source/ThirdParty/gtest
|
|
|
|
if [[ $CARCH == "arm" || $CARCH == "armv6h" ]]; then
|
|
patch -p0 -i ../remove_atomics.patch
|
|
fi
|
|
}
|
|
|
|
build() {
|
|
cd build
|
|
|
|
# do not use LLINT assembly for v5/v6
|
|
[[ $CARCH == "arm" || $CARCH == "armv6h" ]] && CONFIG="-DENABLE_JIT=OFF"
|
|
|
|
cmake -G Ninja -DPORT=GTK -DCMAKE_BUILD_TYPE=Release \
|
|
-DCMAKE_SKIP_RPATH=ON -DCMAKE_INSTALL_PREFIX=/usr \
|
|
-DLIB_INSTALL_DIR=/usr/lib -DLIBEXEC_INSTALL_DIR=/usr/lib/webkit2gtk-4.0 \
|
|
-DENABLE_GTKDOC=ON -DPYTHON_EXECUTABLE=/usr/bin/python2 $CONFIG ../webkitgtk-$pkgver
|
|
ninja
|
|
}
|
|
|
|
package() {
|
|
cd build
|
|
DESTDIR="$pkgdir" ninja install
|
|
|
|
cd ../webkitgtk-$pkgver/Source
|
|
while IFS= read -d $'\0' -r _f; do
|
|
echo "### $_f ###"; cat "$_f"; echo
|
|
done < <(find . -name 'COPYING*' -or -name 'LICENSE*' -print0) \
|
|
| install -Dm644 /dev/stdin "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
|
|
}
|