mirror of
https://github.com/archlinuxarm/PKGBUILDs.git
synced 2024-09-19 22:08:32 +00:00
166 lines
5 KiB
Bash
166 lines
5 KiB
Bash
# Maintainer: Antonio Rojas <arojas@archlinux.org>
|
|
# Contributor: Ray Rashif <schiv@archlinux.org>
|
|
# Contributor: Tobias Powalowski <tpowa@archlinux.org>
|
|
|
|
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
|
|
# - remove -DCPU_BASELINE_{ENABLE,DISABLE} flags for SSE
|
|
# - remove cudnn makedepends
|
|
# - remove opencv-cuda package
|
|
|
|
pkgbase=opencv
|
|
pkgname=(opencv
|
|
opencv-samples
|
|
python-opencv)
|
|
pkgver=4.9.0
|
|
pkgrel=8
|
|
pkgdesc='Open Source Computer Vision Library'
|
|
arch=(x86_64)
|
|
license=(Apache-2.0)
|
|
url='https://opencv.org/'
|
|
depends=(abseil-cpp
|
|
cblas
|
|
ffmpeg
|
|
freetype2
|
|
gcc-libs
|
|
glib2
|
|
glibc
|
|
gst-plugins-base
|
|
gst-plugins-base-libs
|
|
gstreamer
|
|
harfbuzz
|
|
lapack
|
|
libdc1394
|
|
libglvnd
|
|
libjpeg-turbo
|
|
libpng
|
|
libtiff
|
|
libwebp
|
|
openexr
|
|
openjpeg2
|
|
verdict
|
|
protobuf
|
|
tbb
|
|
zlib)
|
|
makedepends=(ant
|
|
cmake
|
|
eigen
|
|
fmt
|
|
git
|
|
glew
|
|
hdf5
|
|
java-environment
|
|
lapacke
|
|
mesa
|
|
nlohmann-json
|
|
openmpi
|
|
pugixml
|
|
python-numpy
|
|
python-setuptools
|
|
qt6-5compat
|
|
vtk)
|
|
optdepends=('opencv-samples: samples'
|
|
'vtk: for the viz module'
|
|
'glew: for the viz module'
|
|
'qt6-base: for the HighGUI module'
|
|
'hdf5: for the HDF5 module'
|
|
'opencl-icd-loader: For coding with OpenCL'
|
|
'java-runtime: Java interface')
|
|
source=(git+https://github.com/opencv/opencv#tag=$pkgver
|
|
git+https://github.com/opencv/opencv_contrib#tag=$pkgver
|
|
$pkgname-cccl-2.2.0.zip::https://github.com/NVIDIA/cccl/archive/refs/tags/v2.2.0.zip
|
|
vtk9.patch
|
|
fix-nppi-bufsize-type.patch
|
|
opencv-cudnn9.patch::https://patch-diff.githubusercontent.com/raw/opencv/opencv/pull/25412.patch)
|
|
sha256sums=('b0d2012628b4224c7dd79aa98010586544e16858617c88c807014e11696b2ca3'
|
|
'36ddaddd6f50cf13115ecf1a4777940739c4727e64135a52e768fa28ac163d4a'
|
|
'f0899311b537614f3bb79fcb20e5fa09e72b857ba3e5ef5d13ef64c6710483e7'
|
|
'f35a2d4ea0d6212c7798659e59eda2cb0b5bc858360f7ce9c696c77d3029668e'
|
|
'993032a43a62faecc56f3f7aeaed29e471605dabdf28579fbeb36d52ecaa4060'
|
|
'db2a2dd99e52560e4c8b2ef7d578120f4bdc4232f71c871e732097232c83e2d4')
|
|
|
|
prepare() {
|
|
patch -d $pkgname -p1 < vtk9.patch # Don't require all vtk optdepends
|
|
|
|
# fix type of several buffer size variables (NPP from CUDA 12.4 has breaking API change
|
|
# as several function parameters were changed from `int*` to `size_t*`)
|
|
patch -d opencv_contrib -Np1 < fix-nppi-bufsize-type.patch
|
|
|
|
patch -d opencv -p1 < opencv-cudnn9.patch # Fix build with CUDNN 9
|
|
}
|
|
|
|
build() {
|
|
export JAVA_HOME="/usr/lib/jvm/default"
|
|
# cmake's FindLAPACK doesn't add cblas to LAPACK_LIBRARIES, so we need to specify them manually
|
|
_opts="-DWITH_OPENCL=ON \
|
|
-DWITH_OPENGL=ON \
|
|
-DOpenGL_GL_PREFERENCE=LEGACY \
|
|
-DCMAKE_CXX_STANDARD=17 \
|
|
-DWITH_TBB=ON \
|
|
-DWITH_VULKAN=ON \
|
|
-DWITH_QT=ON \
|
|
-DBUILD_WITH_DEBUG_INFO=OFF \
|
|
-DBUILD_TESTS=OFF \
|
|
-DBUILD_PERF_TESTS=OFF \
|
|
-DBUILD_EXAMPLES=ON \
|
|
-DBUILD_PROTOBUF=OFF \
|
|
-DPROTOBUF_UPDATE_FILES=ON \
|
|
-DINSTALL_C_EXAMPLES=ON \
|
|
-DINSTALL_PYTHON_EXAMPLES=ON \
|
|
-DCMAKE_INSTALL_PREFIX=/usr \
|
|
-DOPENCV_EXTRA_MODULES_PATH=$srcdir/opencv_contrib/modules \
|
|
-DOPENCV_SKIP_PYTHON_LOADER=ON \
|
|
-DLAPACK_LIBRARIES=/usr/lib/liblapack.so;/usr/lib/libblas.so;/usr/lib/libcblas.so \
|
|
-DLAPACK_CBLAS_H=/usr/include/cblas.h \
|
|
-DLAPACK_LAPACKE_H=/usr/include/lapacke.h \
|
|
-DOPENCV_GENERATE_PKGCONFIG=ON \
|
|
-DOPENCV_ENABLE_NONFREE=ON \
|
|
-DOPENCV_JNI_INSTALL_PATH=lib \
|
|
-DOPENCV_GENERATE_SETUPVARS=OFF \
|
|
-DEIGEN_INCLUDE_PATH=/usr/include/eigen3 \
|
|
-DCMAKE_FIND_PACKAGE_PREFER_CONFIG=ON \
|
|
-Dprotobuf_MODULE_COMPATIBLE=ON"
|
|
|
|
cmake -B build -S $pkgname $_opts
|
|
cmake --build build
|
|
}
|
|
|
|
package_opencv() {
|
|
DESTDIR="$pkgdir" cmake --install build
|
|
|
|
# separate samples package
|
|
mv "$pkgdir"/usr/share/opencv4/samples "$srcdir"
|
|
|
|
# Add java symlinks expected by some binary blobs
|
|
ln -sr "$pkgdir"/usr/share/java/{opencv4/opencv-${pkgver//./},opencv}.jar
|
|
ln -sr "$pkgdir"/usr/lib/{libopencv_java${pkgver//./},libopencv_java}.so
|
|
|
|
# Split Python bindings
|
|
rm -r "$pkgdir"/usr/lib/python3*
|
|
}
|
|
|
|
package_opencv-samples() {
|
|
pkgdesc+=' (samples)'
|
|
depends=(opencv)
|
|
unset optdepends
|
|
|
|
mkdir -p "$pkgdir"/usr/share/opencv4
|
|
mv samples "$pkgdir"/usr/share/opencv4
|
|
}
|
|
|
|
package_python-opencv() {
|
|
pkgdesc='Python bindings for OpenCV'
|
|
depends=(fmt
|
|
glew
|
|
hdf5
|
|
jsoncpp
|
|
opencv
|
|
openmpi
|
|
pugixml
|
|
python-numpy
|
|
qt6-base
|
|
vtk)
|
|
unset optdepends
|
|
|
|
DESTDIR="$pkgdir" cmake --install build/modules/python3
|
|
}
|