mirror of
https://github.com/archlinuxarm/PKGBUILDs.git
synced 2024-09-19 22:08:32 +00:00
47 lines
1.9 KiB
Bash
47 lines
1.9 KiB
Bash
# Maintainer: Antonio Rojas <arojas@archlinux,org>
|
|
|
|
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
|
|
# - remove makedepend on vc
|
|
|
|
pkgname=krita
|
|
_pkgver=4.4.8
|
|
pkgver=${_pkgver/-/}
|
|
pkgrel=3
|
|
pkgdesc='Edit and paint images'
|
|
arch=(x86_64)
|
|
url='https://krita.org'
|
|
license=(GPL3)
|
|
depends=(kitemviews kitemmodels ki18n kcompletion kguiaddons kcrash qt5-svg qt5-multimedia quazip
|
|
gsl libraw exiv2 openexr fftw giflib openjpeg2 opencolorio hicolor-icon-theme)
|
|
makedepends=(extra-cmake-modules kdoctools boost eigen poppler-qt5 python-pyqt5 libheif
|
|
qt5-tools sip kseexpr)
|
|
optdepends=('poppler-qt5: PDF filter' 'ffmpeg: to save animations'
|
|
"krita-plugin-gmic: G'MIC plugin" 'python-pyqt5: for the Python plugins' 'libheif: HEIF filter'
|
|
'kseexpr: SeExpr generator layer' 'kimageformats: PSD support')
|
|
source=(https://download.kde.org/stable/krita/$_pkgver/$pkgname-$_pkgver.tar.gz{,.sig}
|
|
krita-openexr3.patch
|
|
krita-opencolorio2.patch)
|
|
sha256sums=('bcc68a5711d92515d6553611a0bddd53f3259843fd3534b9b3e535d7ed430df8'
|
|
'SKIP'
|
|
'3825dac0317f4501c8dd8b0844540bbd0841702cd15903ce3a659755eaa226f5'
|
|
'ca24ada0e2bd620e8abe74eff7adda3526925a9b61a968849d3885084bc13816')
|
|
validpgpkeys=('05D00A8B73A686789E0A156858B9596C722EA3BD' # Boudewijn Rempt <foundation@krita.org>
|
|
'E9FB29E74ADEACC5E3035B8AB69EB4CF7468332F' # Dmitry Kazakov (main key) <dimula73@gmail.com>
|
|
'064182440C674D9F8D0F6F8B4DA79EDA231C852B') # Stichting Krita Foundation <foundation@krita.org>
|
|
|
|
prepare() {
|
|
patch -d $pkgname-$_pkgver -p1 < krita-openexr3.patch # Fix build with OpenEXR 3
|
|
patch -d $pkgname-$_pkgver -p1 < krita-opencolorio2.patch # Fix build with OCIO 2
|
|
}
|
|
|
|
build() {
|
|
cmake -B build -S $pkgname-$_pkgver \
|
|
-DBUILD_TESTING=OFF \
|
|
-DBUILD_KRITA_QT_DESIGNER_PLUGINS=ON
|
|
cmake --build build
|
|
}
|
|
|
|
package() {
|
|
DESTDIR="$pkgdir" cmake --install build
|
|
}
|