mirror of
https://github.com/archlinuxarm/PKGBUILDs.git
synced 2024-11-08 22:45:43 +00:00
67 lines
2 KiB
Bash
67 lines
2 KiB
Bash
# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
|
|
# Contributor: Gaetan Bisson <bisson@archlinux.org>
|
|
# Contributor: Giovanni Scafora <giovanni@archlinux.org>
|
|
# Contributor: James Rayner <james@archlinux.org>
|
|
# Contributor: Partha Chowdhury <kira.laucas@gmail.com>
|
|
|
|
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
|
|
# - remove dependencies on libxnvctrl, libXNVCtrl.so
|
|
# - remove -D BUILD_NVIDIA=ON
|
|
|
|
pkgname=conky
|
|
pkgver=1.12.2
|
|
_gitcommit=52e5aa53b4c76973519a770949dc8bdca0145325
|
|
pkgrel=1
|
|
pkgdesc='Lightweight system monitor for X'
|
|
url='https://github.com/brndnmtthws/conky'
|
|
license=('BSD' 'GPL')
|
|
arch=('x86_64')
|
|
makedepends=('cmake' 'docbook2x' 'docbook-xsl' 'man-db' 'git')
|
|
depends=(
|
|
'glibc' 'glib2' 'lua' 'wireless_tools' 'libxdamage' 'libxinerama' 'libxft' 'imlib2'
|
|
'libxml2' 'libpulse' 'systemd-libs' 'ncurses' 'curl'
|
|
libncursesw.so libsystemd.so libpulse.so libcurl.so)
|
|
source=("git+https://github.com/brndnmtthws/conky.git#tag=${_gitcommit}?signed")
|
|
sha512sums=('SKIP')
|
|
b2sums=('SKIP')
|
|
validpgpkeys=(
|
|
'EB2E847572A71BE20F59AFBEB49ABB7270D9D4FD' # Brenden Matthews
|
|
)
|
|
|
|
pkgver() {
|
|
cd ${pkgname}
|
|
git describe --tags --match 'v*' | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
|
|
}
|
|
|
|
build() {
|
|
cd ${pkgname}
|
|
cmake \
|
|
-B build \
|
|
-D CMAKE_BUILD_TYPE=Release \
|
|
-D MAINTAINER_MODE=ON \
|
|
-D BUILD_DOCS=ON \
|
|
-D BUILD_WLAN=ON \
|
|
-D BUILD_XDBE=ON \
|
|
-D BUILD_XSHAPE=ON \
|
|
-D BUILD_IMLIB2=ON \
|
|
-D BUILD_CURL=ON \
|
|
-D BUILD_RSS=ON \
|
|
-D BUILD_WEATHER_METAR=ON \
|
|
-D BUILD_PULSEAUDIO=ON \
|
|
-D BUILD_JOURNAL=ON \
|
|
-D CMAKE_INSTALL_PREFIX=/usr \
|
|
-Wno-dev \
|
|
-S .
|
|
|
|
make -C build
|
|
}
|
|
|
|
package() {
|
|
cd ${pkgname}
|
|
make -C build DESTDIR="${pkgdir}" install
|
|
install -Dm 644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
|
|
install -Dm 644 extras/vim/syntax/conkyrc.vim -t "${pkgdir}"/usr/share/vim/vimfiles/syntax
|
|
install -Dm 644 extras/vim/ftdetect/conkyrc.vim -t "${pkgdir}"/usr/share/vim/vimfiles/ftdetect
|
|
}
|
|
|
|
# vim: ts=2 sw=2 et:
|