mirror of
https://github.com/archlinuxarm/PKGBUILDs.git
synced 2024-09-19 22:08:32 +00:00
86 lines
3 KiB
Bash
86 lines
3 KiB
Bash
# $Id$
|
|
# Maintainer : Ionut Biru <ibiru@archlinux.org>
|
|
# Contributor: Alexander Baldeck <alexander@archlinux.org>
|
|
# Contributor: Dale Blount <dale@archlinux.org>
|
|
# Contributor: Anders Bostrom <anders.bostrom@home.se>
|
|
|
|
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
|
|
# - mozconfig changes for ARM
|
|
# - patch to remove NEON/SIMD checks from configure
|
|
# - memory saving LDFLAGS
|
|
# - enable calendar in mozconfig
|
|
|
|
buildarch=20
|
|
|
|
pkgname=thunderbird
|
|
pkgver=38.0.1
|
|
pkgrel=1
|
|
pkgdesc="Standalone Mail/News reader"
|
|
arch=('i686' 'x86_64')
|
|
license=('MPL' 'GPL')
|
|
url="http://www.mozilla.org/thunderbird/"
|
|
depends=('gtk2' 'mozilla-common' 'libxt' 'startup-notification' 'mime-types'
|
|
'dbus-glib' 'alsa-lib' 'desktop-file-utils' 'hicolor-icon-theme'
|
|
'libvpx' 'icu' 'libevent' 'nss' 'hunspell' 'sqlite')
|
|
makedepends=('unzip' 'zip' 'python2' 'wireless_tools' 'yasm' 'mesa' 'libpulse')
|
|
optdepends=('libcanberra: for sound support')
|
|
install=thunderbird.install
|
|
source=(https://ftp.mozilla.org/pub/mozilla.org/thunderbird/releases/$pkgver/source/thunderbird-$pkgver.source.tar.bz2
|
|
mozconfig
|
|
thunderbird.desktop
|
|
thunderbird-install-dir.patch
|
|
vendor.js
|
|
no-neon.patch)
|
|
options=('!emptydirs' '!makeflags')
|
|
sha256sums=('7655039a9a2d5d169f5b43d2c737007dbaa42fa767f7bfbfde8ae46b05e4ab71'
|
|
'25085e4f147174f88541896673f741a968a6acf13c3f10432e81083416ef5611'
|
|
'3fba13d88aeb003ab0811ef739463858172ce0662a1c7d62835df3d83ddbb8fb'
|
|
'24599eab8862476744fe1619a9a53a5b8cdcab30b3fc5767512f31d3529bd05d'
|
|
'e4ea8e6788163d9f8db8f1f40023db3ea0a1358f9a4510169f2d4c4fe6a887ed'
|
|
'1ecdb17848df46c1820bcf071b24e588f29f99ba860821d2b960c75f4ff1c6a4')
|
|
|
|
prepare() {
|
|
cd comm-esr${pkgver%%.*}
|
|
patch -Np1 -i ../thunderbird-install-dir.patch
|
|
|
|
patch -Np0 -i ../no-neon.patch
|
|
|
|
cp "$srcdir/mozconfig" .mozconfig
|
|
|
|
# configure script misdetects the preprocessor without an optimization level
|
|
# https://bugs.archlinux.org/task/34644
|
|
sed -i '/ac_cpp=/s/$CPPFLAGS/& -O2/' mozilla/configure
|
|
}
|
|
|
|
build() {
|
|
cd comm-esr${pkgver%%.*}
|
|
|
|
export LDFLAGS="$LDFLAGS -Wl,--no-keep-memory -Wl,--reduce-memory-overheads"
|
|
export PYTHON="/usr/bin/python2"
|
|
|
|
make -f client.mk build
|
|
}
|
|
|
|
package() {
|
|
cd comm-esr${pkgver%%.*}
|
|
make -f client.mk DESTDIR="$pkgdir" install
|
|
|
|
install -Dm644 ../vendor.js "$pkgdir/usr/lib/thunderbird/defaults/preferences/vendor.js"
|
|
|
|
for i in 16 22 24 32 48 256; do
|
|
install -Dm644 other-licenses/branding/thunderbird/mailicon$i.png \
|
|
"$pkgdir/usr/share/icons/hicolor/${i}x${i}/apps/thunderbird.png"
|
|
done
|
|
|
|
install -Dm644 ../thunderbird.desktop \
|
|
"$pkgdir/usr/share/applications/thunderbird.desktop"
|
|
|
|
# Use system-provided dictionaries
|
|
rm -rf "$pkgdir"/usr/lib/thunderbird/{dictionaries,hyphenation}
|
|
ln -sf /usr/share/hunspell "$pkgdir/usr/lib/thunderbird/dictionaries"
|
|
ln -sf /usr/share/hyphen "$pkgdir/usr/lib/thunderbird/hyphenation"
|
|
|
|
# Remove development stuff
|
|
rm -r "$pkgdir"/usr/{include,lib/thunderbird-devel-*,share/idl}
|
|
}
|