mirror of
https://github.com/archlinuxarm/PKGBUILDs.git
synced 2024-09-19 22:08:32 +00:00
96 lines
3.4 KiB
Bash
96 lines
3.4 KiB
Bash
# Maintainer: Ray Rashif <schiv@archlinux.org>
|
|
# Contributor: Tobias Powalowski <tpowa@archlinux.org>
|
|
|
|
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
|
|
# - remove -DCPU_BASELINE_{ENABLE,DISABLE} flags for SSE
|
|
# - link with libatomic on v5/v6
|
|
|
|
pkgbase=opencv
|
|
pkgname=(opencv opencv-samples)
|
|
pkgver=4.5.1
|
|
pkgrel=1
|
|
pkgdesc="Open Source Computer Vision Library"
|
|
arch=(x86_64)
|
|
license=(BSD)
|
|
url="https://opencv.org/"
|
|
depends=(tbb openexr gst-plugins-base libdc1394 cblas lapack libgphoto2 openjpeg2 ffmpeg)
|
|
makedepends=(cmake python-numpy python-setuptools mesa eigen hdf5 lapacke qt5-base vtk glew ant java-environment)
|
|
optdepends=('opencv-samples: samples'
|
|
'vtk: for the viz module'
|
|
'qt5-base: for the HighGUI module and the Python bindings'
|
|
'hdf5: for the HDF5 module and the Python bindings'
|
|
'opencl-icd-loader: For coding with OpenCL'
|
|
'python-numpy: Python bindings'
|
|
'java-runtime: Java interface')
|
|
source=("$pkgbase-$pkgver.tar.gz::https://github.com/opencv/opencv/archive/$pkgver.zip"
|
|
"opencv_contrib-$pkgver.tar.gz::https://github.com/opencv/opencv_contrib/archive/$pkgver.tar.gz"
|
|
0001-link-with-libatomic.patch)
|
|
sha256sums=('5fbc26ee09e148a4d494b225d04217f7c913ca1a4d46115b70cca3565d7bbe05'
|
|
'12c3b1ddd0b8c1a7da5b743590a288df0934e5cef243e036ca290c2e45e425f5'
|
|
'3376bc87ac7404c6f396f1bee03b76ab0e5cb18829f535bbc97cef71d28ab168')
|
|
|
|
|
|
prepare() {
|
|
cd $pkgname-$pkgver
|
|
if [[ $CARCH == "arm" || $CARCH == "armv6h" ]]; then
|
|
patch -p1 -i ../0001-link-with-libatomic.patch
|
|
fi
|
|
}
|
|
|
|
build() {
|
|
export JAVA_HOME="/usr/lib/jvm/default"
|
|
# cmake's FindLAPACK doesn't add cblas to LAPACK_LIBRARIES, so we need to specify them manually
|
|
_pythonpath=`python -c "from sysconfig import get_path; print(get_path('platlib'))"`
|
|
cmake -B build -S $pkgname-$pkgver \
|
|
-DWITH_OPENCL=ON \
|
|
-DWITH_OPENGL=ON \
|
|
-DWITH_TBB=ON \
|
|
-DWITH_VULKAN=ON \
|
|
-DWITH_QT=ON \
|
|
-DBUILD_WITH_DEBUG_INFO=OFF \
|
|
-DBUILD_TESTS=OFF \
|
|
-DBUILD_PERF_TESTS=OFF \
|
|
-DBUILD_EXAMPLES=ON \
|
|
-DINSTALL_C_EXAMPLES=ON \
|
|
-DINSTALL_PYTHON_EXAMPLES=ON \
|
|
-DCMAKE_INSTALL_PREFIX=/usr \
|
|
-DOPENCV_EXTRA_MODULES_PATH="$srcdir/opencv_contrib-$pkgver/modules" \
|
|
-DOPENCV_SKIP_PYTHON_LOADER=ON \
|
|
-DOPENCV_PYTHON3_INSTALL_PATH=$_pythonpath \
|
|
-DLAPACK_LIBRARIES="/usr/lib/liblapack.so;/usr/lib/libblas.so;/usr/lib/libcblas.so" \
|
|
-DLAPACK_CBLAS_H="/usr/include/cblas.h" \
|
|
-DLAPACK_LAPACKE_H="/usr/include/lapacke.h" \
|
|
-DOPENCV_GENERATE_PKGCONFIG=ON \
|
|
-DOPENCV_ENABLE_NONFREE=ON \
|
|
-DOPENCV_JNI_INSTALL_PATH=lib \
|
|
-DOPENCV_GENERATE_SETUPVARS=OFF \
|
|
-DEIGEN_INCLUDE_PATH=/usr/include/eigen3
|
|
cmake --build build
|
|
}
|
|
|
|
package_opencv() {
|
|
DESTDIR="$pkgdir" cmake --install build
|
|
|
|
# install license file
|
|
install -Dm644 $pkgname-$pkgver/LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
|
|
|
|
# separate samples package
|
|
mv "$pkgdir"/usr/share/opencv4/samples "$srcdir"
|
|
|
|
# Add java symlinks expected by some binary blobs
|
|
ln -sr "$pkgdir"/usr/share/java/{opencv4/opencv-${pkgver//./},opencv}.jar
|
|
ln -sr "$pkgdir"/usr/lib/{libopencv_java${pkgver//./},libopencv_java}.so
|
|
}
|
|
|
|
package_opencv-samples() {
|
|
pkgdesc+=" (samples)"
|
|
depends=("opencv=$pkgver")
|
|
unset optdepends
|
|
|
|
mkdir -p "$pkgdir"/usr/share/opencv4
|
|
mv samples "$pkgdir"/usr/share/opencv4
|
|
|
|
# install license file
|
|
install -Dm644 opencv-$pkgver/LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
|
|
}
|