mirror of
https://github.com/archlinuxarm/PKGBUILDs.git
synced 2024-12-08 23:03:46 +00:00
56 lines
1.4 KiB
Bash
56 lines
1.4 KiB
Bash
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
|
|
# Contributor: Alexander Rødseth <rodseth@gmail.com>
|
|
# Contributor: Jon Nordby <jononor@gmail.com>
|
|
|
|
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
|
|
# - disable neon on !AArch64
|
|
|
|
pkgname=libwebp
|
|
pkgver=1.0.1
|
|
pkgrel=1
|
|
pkgdesc="WebP library and conversion tools"
|
|
arch=(x86_64)
|
|
url="https://developers.google.com/speed/webp/"
|
|
license=(BSD)
|
|
depends=(libpng libjpeg libtiff giflib)
|
|
makedepends=(freeglut mesa glu git)
|
|
optdepends=('freeglut: vwebp viewer')
|
|
_commit=e85d3313d6d52b1e9c6c181b488fc0831a747de8 # tags/v1.0.1^0
|
|
source=("git+https://chromium.googlesource.com/webm/libwebp#commit=$_commit")
|
|
sha256sums=('SKIP')
|
|
validpgpkeys=('6B0E6B70976DE303EDF2F601F9C3D6BDB8232B5D')
|
|
|
|
pkgver() {
|
|
cd $pkgname
|
|
git describe --tags | sed 's/^v//;s/-/+/g'
|
|
}
|
|
|
|
prepare() {
|
|
cd $pkgname
|
|
NOCONFIGURE=1 ./autogen.sh
|
|
}
|
|
|
|
build() {
|
|
cd $pkgname
|
|
[[ $CARCH != "aarch64" ]] && CONFIG="--disable-neon"
|
|
./configure --prefix=/usr \
|
|
--enable-swap-16bit-csp \
|
|
--enable-experimental \
|
|
--enable-libwebp{mux,demux,decoder,extras} \
|
|
--disable-static $CONFIG
|
|
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
|
|
make
|
|
}
|
|
|
|
check() {
|
|
cd $pkgname
|
|
make check
|
|
}
|
|
|
|
package() {
|
|
cd $pkgname
|
|
make DESTDIR="$pkgdir" install
|
|
install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
|
|
}
|
|
|
|
# vim:set ts=2 sw=2 et:
|