mirror of
https://github.com/archlinuxarm/PKGBUILDs.git
synced 2024-11-08 22:45:43 +00:00
83 lines
3 KiB
Bash
83 lines
3 KiB
Bash
# $Id$
|
|
# Maintainer : Ionut Biru <ibiru@archlinux.org>
|
|
# Contributor: Alexander Baldeck <alexander@archlinux.org>
|
|
# Contributor: Dale Blount <dale@archlinux.org>
|
|
# Contributor: Anders Bostrom <anders.bostrom@home.se>
|
|
|
|
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
|
|
# - mozconfig changes for ARM
|
|
# - patch to remove NEON/SIMD checks from configure
|
|
# - memory saving LDFLAGS
|
|
# - enable calendar in mozconfig
|
|
|
|
buildarch=20
|
|
|
|
pkgname=thunderbird
|
|
pkgver=24.3.0
|
|
pkgrel=1.1
|
|
pkgdesc="Standalone Mail/News reader"
|
|
arch=('i686' 'x86_64')
|
|
license=('MPL' 'GPL')
|
|
url="http://www.mozilla.org/thunderbird/"
|
|
depends=('alsa-lib' 'dbus-glib' 'desktop-file-utils' 'gtk2' 'hicolor-icon-theme' 'hunspell' 'libevent' 'libvpx' 'libxt' 'mime-types' 'mozilla-common' 'nss' 'sqlite' 'startup-notification')
|
|
makedepends=('unzip' 'zip' 'pkg-config' 'python2' 'wireless_tools' 'yasm' 'mesa' 'autoconf2.13')
|
|
optdepends=('libcanberra: for sound support')
|
|
install=thunderbird.install
|
|
source=(https://ftp.mozilla.org/pub/mozilla.org/thunderbird/releases/$pkgver/source/thunderbird-$pkgver.source.tar.bz2{,.asc}
|
|
mozconfig
|
|
thunderbird.desktop
|
|
thunderbird-install-dir.patch
|
|
vendor.js
|
|
no-neon.patch)
|
|
options=(!emptydirs)
|
|
sha256sums=('b8cc29ed8e3d1bd9d410b8c6c2c069c38ded11844121f93a6fa1b0d1d753e51d'
|
|
'SKIP'
|
|
'84adca3cc1ed19cd4fce8c5cdb21923f8266246595b53e5a469d0c4cf57680f2'
|
|
'd506b771e765e09e2e039b975e25befade8eec97e8950813a32463604955ab4e'
|
|
'929a7ceca0e90d0635a2099b7df24033e865fb5b5b8c5824468c4561c21c377d'
|
|
'e4ea8e6788163d9f8db8f1f40023db3ea0a1358f9a4510169f2d4c4fe6a887ed'
|
|
'e9c75dbc86d96efec6f8bb4fea949fafe20d72bfefacc427decbd7fab801bd00')
|
|
|
|
prepare() {
|
|
cd comm-esr24
|
|
patch -Np1 -i "$srcdir/thunderbird-install-dir.patch"
|
|
|
|
patch -Np0 -i ../no-neon.patch
|
|
|
|
cp "$srcdir/mozconfig" .mozconfig
|
|
|
|
# configure script misdetects the preprocessor without an optimization level
|
|
# https://bugs.archlinux.org/task/34644
|
|
sed -i '/ac_cpp=/s/$CPPFLAGS/& -O2/' mozilla/configure
|
|
}
|
|
|
|
build() {
|
|
cd comm-esr24
|
|
|
|
export LDFLAGS="$LDFLAGS -Wl,-rpath,/usr/lib/thunderbird -Wl,--no-keep-memory -Wl,--reduce-memory-overheads"
|
|
export PYTHON="/usr/bin/python2"
|
|
|
|
make -j1 -f client.mk build MOZ_MAKE_FLAGS="$MAKEFLAGS"
|
|
}
|
|
|
|
package() {
|
|
cd comm-esr24
|
|
make -j1 -f client.mk DESTDIR="$pkgdir" install
|
|
|
|
install -Dm644 "$srcdir"/vendor.js "$pkgdir/usr/lib/thunderbird/defaults/preferences/vendor.js"
|
|
|
|
for i in 16x16 22x22 24x24 32x32 48x48 256x256; do
|
|
install -Dm644 other-licenses/branding/thunderbird/mailicon${i/x*/}.png \
|
|
"$pkgdir/usr/share/icons/hicolor/$i/apps/thunderbird.png"
|
|
done
|
|
|
|
install -Dm644 "$srcdir/thunderbird.desktop" \
|
|
"$pkgdir/usr/share/applications/thunderbird.desktop"
|
|
|
|
rm -rf "$pkgdir"/usr/lib/thunderbird/{dictionaries,hyphenation}
|
|
ln -sf /usr/share/hunspell "$pkgdir/usr/lib/thunderbird/dictionaries"
|
|
ln -sf /usr/share/hyphen "$pkgdir/usr/lib/thunderbird/hyphenation"
|
|
|
|
# We don't want the development stuff
|
|
rm -r "$pkgdir"/usr/{include,lib/thunderbird-devel,share/idl}
|
|
}
|