mirror of
https://github.com/archlinuxarm/PKGBUILDs.git
synced 2024-11-18 22:54:00 +00:00
53 lines
1.4 KiB
Bash
53 lines
1.4 KiB
Bash
# $Id$
|
|
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
|
|
|
|
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
|
|
# - patch to fix build on ARM
|
|
|
|
pkgname=gnome-builder
|
|
pkgver=3.22.1
|
|
pkgrel=1
|
|
pkgdesc="An IDE for writing GNOME-based software"
|
|
url="https://wiki.gnome.org/Apps/Builder"
|
|
arch=(i686 x86_64)
|
|
license=(GPL3)
|
|
depends=(gtksourceview3 devhelp libgit2-glib gjs python-gobject clang desktop-file-utils
|
|
ctags libpeas vte3 vala python-jedi)
|
|
makedepends=(intltool llvm gobject-introspection gtk-doc yelp-tools autoconf-archive
|
|
appstream-glib vala git mm-common)
|
|
groups=(gnome-extra)
|
|
_commit=74531b2d7a474f3f9edf5c215d7284fe0b022ec9 # tags/GNOME_BUILDER_3_22_1^0
|
|
source=("git://git.gnome.org/gnome-builder#commit=$_commit"
|
|
'0001-ARM-fix.patch')
|
|
sha256sums=('SKIP'
|
|
'a92b25439576fe44565d3d7517be5f22d386806916fbc4abd1b3b304ed7b7ca2')
|
|
|
|
|
|
pkgver() {
|
|
cd $pkgname
|
|
git describe --tags | sed 's/^GNOME_BUILDER_//;s/_/./g;s/-/+/g'
|
|
}
|
|
|
|
prepare() {
|
|
cd $pkgname
|
|
git apply ../0001-ARM-fix.patch
|
|
NOCONFIGURE=1 ./autogen.sh
|
|
}
|
|
|
|
build() {
|
|
cd $pkgname
|
|
./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
|
|
--libexecdir=/usr/lib --enable-gtk-doc
|
|
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
|
|
make
|
|
}
|
|
|
|
check() {
|
|
cd $pkgname
|
|
make -k check || :
|
|
}
|
|
|
|
package() {
|
|
cd $pkgname
|
|
make DESTDIR="$pkgdir" install
|
|
}
|