mirror of
https://github.com/archlinuxarm/PKGBUILDs.git
synced 2024-11-08 22:45:43 +00:00
67 lines
2.7 KiB
Bash
67 lines
2.7 KiB
Bash
# Maintainer: Alexander Rødseth <rodseth@gmail.com>
|
||
# Maintainer: Felix Yan <felixonmars@archlinux.org>
|
||
# Maintainer: Orhun Parmaksız <orhun@archlinux.org>
|
||
# Contributor: T. Jameson Little <t.jameson.little at gmail dot com>
|
||
# Contributor: Usagi Ito <usagi@WonderRabbitProject.net>
|
||
# Contributor: siasia <http://pastebin.com/qsBEmNCw>
|
||
# Contributor: Julien Nicoulaud <julien.nicoulaud@gmail.com>
|
||
# Contributor: Jacob Bang <julemand101gmail.com>
|
||
|
||
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
|
||
# - added source and sha512 for ARMv7h, AArch64 builds of Dart
|
||
|
||
pkgname=dart
|
||
pkgver=2.17.3
|
||
pkgrel=1
|
||
pkgdesc='The dart programming language SDK'
|
||
arch=('x86_64' 'armv7h' 'aarch64')
|
||
url='https://www.dartlang.org/'
|
||
depends=('bash')
|
||
license=('BSD')
|
||
makedepends=('setconf')
|
||
options=('!strip')
|
||
source_x86_64+=("$pkgname-$pkgver-64.zip::https://storage.googleapis.com/dart-archive/channels/stable/release/$pkgver/sdk/dartsdk-linux-x64-release.zip")
|
||
source_armv7h+=("$pkgname-$pkgver-arm.zip::https://storage.googleapis.com/dart-archive/channels/stable/release/$pkgver/sdk/dartsdk-linux-arm-release.zip")
|
||
source_aarch64+=("$pkgname-$pkgver-arm64.zip::https://storage.googleapis.com/dart-archive/channels/stable/release/$pkgver/sdk/dartsdk-linux-arm64-release.zip")
|
||
sha512sums_x86_64=('53a5439d5924c88636ec544444b35e070e61ee69c45f947d514687040967b06e15dff6241ab74c9928e0ef4d4eb3efbf8587a1275ab440cf32bda2c89aba886e')
|
||
sha512sums_armv7h=('48db2aca6e0fe0ed10fa1c966d05f73eafc19c35d4ee9a63b4656d1c1d3d55e7b9814b870da68b014d6ae2346774c0ff1f4c9aeb15de43985e2c4fab221e5c6a')
|
||
sha512sums_aarch64=('9fa692d61548cbfd22861cbbd4ded61e4527ab59fcc1a57d5005429e39b31850c35a624d2e3e00e6e981537443152f7e0504985a53974e4dbe4fd181b09aeb4b')
|
||
|
||
prepare() {
|
||
# Fix permissions
|
||
find "$pkgname-sdk" -type d -exec chmod a+rx '{}' + \
|
||
-or -type f -exec chmod a+r '{}' +
|
||
|
||
cd "$pkgname-sdk/bin"
|
||
|
||
# Configure paths
|
||
for _f in dart2js dartdevc; do
|
||
setconf $_f BIN_DIR "/opt/$pkgname-sdk/bin"
|
||
setconf $_f PROG_NAME "/opt/$pkgname-sdk/bin/$_f"
|
||
setconf $_f SDK_DIR "/opt/$pkgname-sdk/"
|
||
done
|
||
|
||
# Extract license (AUTHORS and LICENSE files are missing)
|
||
head -n5 "../include/dart_api.h" > ../../LICENSE
|
||
}
|
||
|
||
package() {
|
||
# Create directories
|
||
install -d "$pkgdir"{"/opt/$pkgname-sdk",/usr/{bin,"share/doc/$pkgname"}}
|
||
|
||
# Package the files
|
||
cp -a "$pkgname-sdk/"* "$pkgdir/opt/$pkgname-sdk/"
|
||
|
||
# Set up symbolic links for the executables
|
||
for f in dart dart2js dartdevc dartaotruntime; do
|
||
ln -s "/opt/$pkgname-sdk/bin/$f" "$pkgdir/usr/bin/$f"
|
||
done
|
||
|
||
# Package documentation
|
||
install -Dm644 "$pkgdir/opt/$pkgname-sdk/README" -t "$pkgdir/usr/share/doc/$pkgname"
|
||
|
||
# BSD License
|
||
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
|
||
}
|
||
|
||
# vim:set ts=2 sw=2 et:
|