mirror of
https://github.com/archlinuxarm/PKGBUILDs.git
synced 2024-11-08 22:45:43 +00:00
78 lines
2.8 KiB
Bash
78 lines
2.8 KiB
Bash
# Maintainer: Antonio Rojas <arojas@archlinux.org>
|
|
# Maintainer: Felix Yan <felixonmars@archlinux.org>
|
|
# Contributor: Andrea Scarpino <andrea@archlinux.org>
|
|
|
|
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
|
|
# - disable ibase for now, FTBFS
|
|
|
|
pkgname=qt6-base
|
|
_qtver=6.4.0
|
|
pkgver=${_qtver/-/}
|
|
pkgrel=3
|
|
arch=(x86_64)
|
|
url='https://www.qt.io'
|
|
license=(GPL3 LGPL3 FDL custom)
|
|
pkgdesc='A cross-platform application and UI framework'
|
|
depends=(libjpeg-turbo xcb-util-keysyms xcb-util-cursor libgl fontconfig xdg-utils
|
|
shared-mime-info xcb-util-wm libxrender libxi sqlite mesa vulkan-headers
|
|
tslib libinput libxkbcommon-x11 libproxy libcups double-conversion brotli libb2 md4c)
|
|
makedepends=(cmake ninja libfbclient mariadb-libs unixodbc postgresql alsa-lib gst-plugins-base-libs
|
|
gtk3 libpulse cups freetds xmlstarlet)
|
|
optdepends=('qt6-wayland: to run Qt6 applications in a Wayland session'
|
|
'postgresql-libs: PostgreSQL driver'
|
|
'mariadb-libs: MariaDB driver'
|
|
'unixodbc: ODBC driver'
|
|
'libfbclient: Firebird/iBase driver'
|
|
'freetds: MS SQL driver'
|
|
'gtk3: GTK platform plugin'
|
|
'perl: for syncqt')
|
|
groups=(qt6)
|
|
options=(debug)
|
|
_pkgfn=${pkgname/6-/}-everywhere-src-$_qtver
|
|
source=(https://download.qt.io/official_releases/qt/${pkgver%.*}/$_qtver/submodules/$_pkgfn.tar.xz
|
|
qt6-base-cflags.patch
|
|
qt6-base-nostrip.patch)
|
|
sha256sums=('cb6475a0bd8567c49f7ffbb072a05516ee6671171bed55db75b22b94ead9b37d'
|
|
'5411edbe215c24b30448fac69bd0ba7c882f545e8cf05027b2b6e2227abc5e78'
|
|
'4b93f6a79039e676a56f9d6990a324a64a36f143916065973ded89adc621e094')
|
|
|
|
prepare() {
|
|
patch -d $_pkgfn -p1 < qt6-base-cflags.patch # Use system CFLAGS
|
|
patch -d $_pkgfn -p1 < qt6-base-nostrip.patch # Don't strip binaries with qmake
|
|
}
|
|
|
|
build() {
|
|
cmake -B build -S $_pkgfn -G Ninja \
|
|
-DCMAKE_INSTALL_PREFIX=/usr \
|
|
-DCMAKE_BUILD_TYPE=RelWithDebInfo \
|
|
-DINSTALL_BINDIR=lib/qt6/bin \
|
|
-DINSTALL_PUBLICBINDIR=usr/bin \
|
|
-DINSTALL_LIBEXECDIR=lib/qt6 \
|
|
-DINSTALL_DOCDIR=share/doc/qt6 \
|
|
-DINSTALL_ARCHDATADIR=lib/qt6 \
|
|
-DINSTALL_DATADIR=share/qt6 \
|
|
-DINSTALL_INCLUDEDIR=include/qt6 \
|
|
-DINSTALL_MKSPECSDIR=lib/qt6/mkspecs \
|
|
-DINSTALL_EXAMPLESDIR=share/doc/qt6/examples \
|
|
-DQT_FEATURE_journald=ON \
|
|
-DQT_FEATURE_openssl_linked=ON \
|
|
-DQT_FEATURE_system_sqlite=ON \
|
|
-DQT_FEATURE_system_xcb_xinput=ON \
|
|
-DQT_FEATURE_sql_ibase=OFF \
|
|
-DCMAKE_MESSAGE_LOG_LEVEL=STATUS
|
|
cmake --build build
|
|
}
|
|
|
|
package() {
|
|
depends+=(qt6-translations)
|
|
DESTDIR="$pkgdir" cmake --install build
|
|
|
|
install -Dm644 $_pkgfn/LICENSES/* -t "$pkgdir"/usr/share/licenses/$pkgbase
|
|
|
|
# Install symlinks for user-facing tools
|
|
cd "$pkgdir"
|
|
mkdir usr/bin
|
|
while read _line; do
|
|
ln -s $_line
|
|
done < "$srcdir"/build/user_facing_tool_links.txt
|
|
}
|