mirror of
https://github.com/archlinuxarm/PKGBUILDs.git
synced 2024-11-08 22:45:43 +00:00
56 lines
1.3 KiB
Bash
56 lines
1.3 KiB
Bash
# Maintainer: Maxime Gauduin <alucryd@archlinux.org>
|
|
# Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
|
|
# Contributor: kfgz <kfgz@interia.pl>
|
|
|
|
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
|
|
# - patch to attempt fixing ARM hackery by bandwagoning developers
|
|
# - retain 10/12 bit separation for AArch64
|
|
# - disable all ARM assembly - version 2.8 broke ARM support completely
|
|
# - patch from upstream bug https://bitbucket.org/multicoreware/x265/issues/442
|
|
|
|
pkgname=x265
|
|
pkgver=3.5
|
|
pkgrel=1
|
|
pkgdesc='Open Source H265/HEVC video encoder'
|
|
arch=(x86_64)
|
|
url=https://bitbucket.org/multicoreware/x265_git
|
|
license=(GPL)
|
|
depends=(gcc-libs)
|
|
makedepends=(
|
|
cmake
|
|
git
|
|
nasm
|
|
ninja
|
|
)
|
|
provides=(libx265.so)
|
|
_tag=f0c1022b6be121a753ff02853fbe33da71988656
|
|
source=(git+https://bitbucket.org/multicoreware/x265_git#tag=${_tag}
|
|
arm.patch)
|
|
sha256sums=('SKIP'
|
|
'067b934ae83339deedc58608d272529a004789c3e2819b94636d66a5806fd64b')
|
|
|
|
pkgver() {
|
|
cd x265_git
|
|
|
|
git describe --tags
|
|
}
|
|
|
|
prepare() {
|
|
cd x265_git
|
|
patch -p1 -i ../arm.patch
|
|
}
|
|
|
|
build() {
|
|
[[ $CARCH != "aarch64" ]] && CONFIG="-DENABLE_ASSEMBLY=OFF"
|
|
cmake -S x265_git/source -B build -G Ninja \
|
|
-DCMAKE_INSTALL_PREFIX=/usr \
|
|
-DENABLE_SHARED=TRUE \
|
|
$CONFIG
|
|
ninja -C build
|
|
}
|
|
|
|
package() {
|
|
DESTDIR="${pkgdir}" ninja -C build install
|
|
}
|
|
|
|
# vim: ts=2 sw=2 et:
|