archlinuxarm/PKGBUILDs
1
0
Fork 0
mirror of https://github.com/archlinuxarm/PKGBUILDs.git synced 2024-11-28 22:57:37 +00:00
Code Issues Projects Releases Packages Wiki Activity Actions
PKGBUILDs/extra/libreoffice-fresh/PKGBUILD
Kevin Mihelich 9f5df1904d extra/libreoffice-fresh to 6.4.3-2
2020-05-01 13:01:46 +00:00

387 lines
17 KiB
Bash
Raw Blame History

# Maintainer: AndyRTR <andyrtr@archlinux.org>
# Maintainer: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
# - disable firebird until libfbclient is updated
# - specify a US mirror
# - make build-nocheck
buildarch=12
highmem=1
# Google API keys (see http://www.chromium.org/developers/how-tos/api-keys)
# Note: These are for Arch Linux use ONLY. For your own distribution, please
# get your own set of keys. Feel free to contact foutrelis@archlinux.org for
# more information.
_google_default_client_id=413772536636.apps.googleusercontent.com
_google_default_client_secret=0ZChLK6AxeA3Isu96MkwqDR4
pkgbase=libreoffice-fresh
pkgname=('libreoffice-fresh-sdk' 'libreoffice-fresh')
_LOver=6.4.3.2
pkgver=6.4.3
pkgrel=2
arch=('x86_64')
license=('LGPL3')
url="https://www.libreoffice.org/"
makedepends=('curl>=7.20.0' 'hunspell>=1.2.8' 'python>=3.7' 'libwpd>=0.9.2' 'libwps'
'neon>=0.28.6' 'pango' 'nspr' 'libjpeg' 'libxrandr' 'libgl' 'dbus-glib'
'libxslt' 'redland' 'hyphen' 'lpsolve' 'gcc-libs' 'sh' 'graphite' 'icu'
'lcms2' 'poppler>=0.24.0' 'libvisio' 'libetonyek' 'libodfgen' 'libcdr'
'libmspub' 'harfbuzz-icu' 'nss' 'hicolor-icon-theme'
'desktop-file-utils' 'shared-mime-info' 'gst-plugins-base-libs' #'gtk2'
'sane' 'perl-archive-zip' 'zip' 'unzip' 'unixodbc' 'ant'
'gperf' 'gtk3' 'qt5-base' 'plasma-framework' 'cppunit' 'beanshell' 'clucene'
'junit' 'libmythes' 'libwpg' 'java-environment=8' 'postgresql-libs' 'mariadb-libs' 'libgl'
'bluez-libs' 'gdb' 'doxygen' 'libatomic_ops' 'mdds'
'apr' 'serf' 'ttf-liberation' 'ttf-dejavu' 'ttf-carlito' 'libxinerama' 'libpagemaker' 'glm'
'libabw' 'libmwaw' 'libe-book' 'coin-or-mp' 'liblangtag' 'liborcus'
'libexttextcat' 'libcmis' 'gobject-introspection' # 'libfbclient'
'libtommath' 'libzmf' 'gpgme' 'xmlsec' 'rxvt-unicode'
'libepubgen' 'libfreehand' 'libqxp' 'libstaroffice' 'boost' 'libnumbertext'
'libffi'
)
_mirror="https://download.documentfoundation.org/libreoffice/src/${pkgver}"
#_mirror="https://dev-builds.libreoffice.org/pre-releases/src"
_additional_source_url="https://dev-www.libreoffice.org/src"
_additional_source_url2="https://dev-www.libreoffice.org/extern"
source=(${_mirror}/libreoffice{,-help,-translations}-${_LOver}.tar.xz{,.asc}
${_additional_source_url}/35c94d2df8893241173de1d16b6034c0-swingExSrc.zip
${_additional_source_url}/798b2ffdc8bcfe7bca2cf92b62caf685-rhino1_5R5.zip # keep old bundled version, new system version ftbs
${_additional_source_url}/a7983f859eafb2677d7ff386a023bc40-xsltml_2.1.2.zip
${_additional_source_url}/0168229624cfac409e766913506961a8-ucpp-1.3.2.tar.gz
${_additional_source_url}/language-subtag-registry-2019-04-03.tar.bz2
${_additional_source_url}/17410483b5b5f267aa18b7e00b65e6e0-hsqldb_1_8_0.zip
${_additional_source_url}/d8bd5eed178db6e2b18eeed243f85aa8-flute-1.1.6.zip
${_additional_source_url}/ba2930200c9f019c2d93a8c88c651a0f-flow-engine-0.9.4.zip
${_additional_source_url}/pdfium-3963.tar.bz2
${_additional_source_url}/lxml-4.1.1.tgz
${_additional_source_url}/Firebird-3.0.0.32483-0.tar.bz2
${_additional_source_url}/QR-Code-generator-1.4.0.tar.gz
${_additional_source_url2}/8249374c274932a21846fa7629c2aa9b-officeotron-0.7.4-master.jar # for test suite
${_additional_source_url2}/odfvalidator-1.2.0-incubating-SNAPSHOT-jar-with-dependencies-971c54fd38a968f5860014b44301872706f9e540.jar # for test suite
${_additional_source_url2}/884ed41809687c3e168fc7c19b16585149ff058eca79acbf3ee784f6630704cc-opens___.ttf
${_additional_source_url2}/185d60944ea767075d27247c3162b3bc-unowinreg.dll
make-pyuno-work-with-system-wide-module-install.diff
soffice-template.desktop.in
libreoffice-fresh.sh libreoffice-fresh.csh
libreoffice-poppler-0.86.patch)
noextract=(35c94d2df8893241173de1d16b6034c0-swingExSrc.zip
798b2ffdc8bcfe7bca2cf92b62caf685-rhino1_5R5.zip
a7983f859eafb2677d7ff386a023bc40-xsltml_2.1.2.zip
0168229624cfac409e766913506961a8-ucpp-1.3.2.tar.gz
language-subtag-registry-2019-04-03.tar.bz2
17410483b5b5f267aa18b7e00b65e6e0-hsqldb_1_8_0.zip
d8bd5eed178db6e2b18eeed243f85aa8-flute-1.1.6.zip
ba2930200c9f019c2d93a8c88c651a0f-flow-engine-0.9.4.zip
pdfium-3963.tar.bz2
lxml-4.1.1.tgz
Firebird-3.0.0.32483-0.tar.bz2
QR-Code-generator-1.4.0.tar.gz
8249374c274932a21846fa7629c2aa9b-officeotron-0.7.4-master.jar # for test suite
odfvalidator-1.2.0-incubating-SNAPSHOT-jar-with-dependencies-971c54fd38a968f5860014b44301872706f9e540.jar # for test suite
884ed41809687c3e168fc7c19b16585149ff058eca79acbf3ee784f6630704cc-opens___.ttf
185d60944ea767075d27247c3162b3bc-unowinreg.dll
)
validpgpkeys=('C2839ECAD9408FBE9531C3E9F434A1EFAFEEAEA3') # LibreOffice Build Team (CODE SIGNING KEY) <build@documentfoundation.org>
sha256sums=('bc14547c188efa15f4cb36cfb3da7cacb3037a7448d1bba8a58ed6a320ccabb2'
'SKIP'
'8570eaa8903e4fb747500adbf06d69d2d3cb6ed3a11a3a804403878f1ecfef56'
'SKIP'
'03260badad37d1d96c9bcac79ee48ab2ab00000aba78c3a4a4accd51c987e91b'
'SKIP'
'64585ac36a81291a58269ec5347e7e3e2e8596dbacb9221015c208191333c6e1'
'1fb458d6aab06932693cc8a9b6e4e70944ee1ff052fa63606e3131df34e21753'
'75823776fb51a9c526af904f1503a7afaaab900fba83eda64f8a41073724c870'
'983941d31ee8d366085cadf28db75eb1f5cb03ba1e5853b98f12f7f51c63b776'
'a1d7fb901764bb8f251d4f686cdf565764f9987d0fb5d9315d54a7366a84822d'
'd30b13f4ba2e3b6a2d4f020c0dee0a9fb9fc6fbcc2d561f36b78da4bf3802370'
'1b5b24f7bc543c0362b667692f78db8bab4ed6dafc6172f104d0bd3757d8a133'
'233f66e8d25c5dd971716d4200203a612a407649686ef3b52075d04b4c9df0dd'
'80d4d6bd8faec226936fcde5521c6e92c0c645126ac3ae72dd2c160ca1749895'
'940caef1ec7c78e0c34b0f6b94fe42d0f2022915ffc78643d28538a5cfd0f40e'
'6994be3555e23226630c587444be19d309b25b0fcf1f87df3b4e3f88943e5860'
'fcdf9fd69fde07ae4dca2351d84271a9de8093002f733b77c70f52f1630f6e4a'
'f2443f27561af52324eee03a1892d9f569adc8db9e7bca55614898bc2a13a770'
'984f2a479df79e27e7b01a5815ac53ae64e07746b882262d8a64566494515504'
'884ed41809687c3e168fc7c19b16585149ff058eca79acbf3ee784f6630704cc'
'eafde646a7dbe46d20c291685b0beac2382174d78d66ee990e229a1bf6e6cec6'
'c463654a73ecfbc242ff109726fb4faecdbfb3d91affafe919b24bea65afb563'
'd0be8099cbee3c9dfda694a828149b881c345b204ab68826f317580aafb50879'
'cd1b25ff390e436c6bffa65c6e12382236e3ccbf8d3aae51b1b59bcaed79fd8a'
'de20f36d45f0fecc2d94176dd3ec7226ab07fa8ffb9b0bc73c200349a9273de1'
'f52ef5d64d7a74ca90bc96614260566720130d91f3764874eac673f6b3336b5e')
prepare() {
cd libreoffice-$_LOver
patch -p1 -i ../libreoffice-poppler-0.86.patch # Fix build with poppler 0.86
# move external sources into place
mkdir "${srcdir}"/ext_sources && pushd "${srcdir}"/ext_sources
for source in "${noextract[@]}"; do
ln -s "${srcdir}"/$source .
done
popd
# unowinreg.dll must be a file not a symlink or the result will become a broken symlink
# /usr/share/libreoffice/sdk/classes/win/unowinreg.dll -> /build/libreoffice/src/185d60944ea767075d27247c3162b3bc-unowinreg.dll
rm "${srcdir}"/ext_sources/185d60944ea767075d27247c3162b3bc-unowinreg.dll
cp -f "${srcdir}"/185d60944ea767075d27247c3162b3bc-unowinreg.dll "${srcdir}"/ext_sources
# fix not upstreamable pyuno paths - FS#54250
patch -Np1 -i "${srcdir}"/make-pyuno-work-with-system-wide-module-install.diff
#use the CFLAGS but remove the LibO overridden ones
for i in $CFLAGS; do
case "$i" in
-O?|-pipe|-Wall|-g|-fexceptions) continue;;
esac
ARCH_FLAGS="$ARCH_FLAGS $i"
done
}
build() {
cd libreoffice-$_LOver
# strip -s from Makeflags in case you use it to shorten build logs
_MAKEFLAGS=${MAKEFLAGS/-s/}
# http://site.icu-project.org/download/61#TOC-Migration-Issues
CPPFLAGS+=' -DU_USING_ICU_NAMESPACE=1'
./autogen.sh --with-build-version="${pkgver}-${pkgrel}" \
--with-vendor="Arch Linux" \
--enable-split-app-modules \
--with-parallelism=${_MAKEFLAGS/-j/} \
--with-external-tar="${srcdir}/ext_sources" \
--disable-fetch-external \
--enable-release-build \
--prefix=/usr --exec-prefix=/usr --sysconfdir=/etc \
--libdir=/usr/lib --mandir=/usr/share/man \
--with-lang="" \
--with-help=html \
--disable-avahi \
--enable-dbus \
--enable-evolution2\
--enable-gio\
--enable-gtk3-kde5 \
--enable-kf5 \
--enable-qt5 \
--enable-gtk3 \
--enable-introspection \
--enable-openssl \
--enable-odk\
--enable-python=system \
--enable-scripting-beanshell \
--enable-scripting-javascript \
--disable-dconf \
--disable-report-builder \
--enable-ext-wiki-publisher \
--enable-ext-nlpsolver \
--without-fonts\
--with-system-apr \
--with-system-libcdr \
--with-system-mdds\
--without-myspell-dicts \
--with-system-libvisio \
--with-system-libcmis \
--with-system-libmspub \
--with-system-libexttextcat \
--with-system-orcus \
--with-system-liblangtag \
--with-system-libodfgen \
--with-system-libmwaw \
--with-system-libetonyek \
--with-system-libfreehand \
--disable-firebird-sdbc \
--without-system-qrcodegen \
--with-system-libtommath \
--with-system-libatomic-ops \
--with-system-libebook \
--with-system-libabw \
--with-system-coinmp \
--with-system-dicts \
--with-external-dict-dir=/usr/share/hunspell \
--with-external-hyph-dir=/usr/share/hyphen \
--with-external-thes-dir=/usr/share/mythes \
--with-system-beanshell \
--with-system-cppunit\
--with-system-graphite\
--with-system-glm \
--with-system-libnumbertext \
--with-system-libwpg \
--with-system-libwps \
--with-system-redland\
--with-system-libzmf \
--with-system-gpgmepp \
--with-system-libstaroffice \
--with-system-serf \
--with-jdk-home="/usr/lib/jvm/default" \
--with-ant-home="/usr/share/ant"\
--with-system-boost\
--with-system-icu \
--with-system-cairo \
--with-system-libs \
--with-system-mythes \
--with-system-headers \
--without-system-hsqldb \
--with-system-clucene \
--with-gdrive-client-id=${_google_default_client_id} \
--with-gdrive-client-secret=${_google_default_client_secret} \
--disable-dependency-tracking
touch src.downloaded
make build-nocheck
mkdir "${srcdir}"/fakeinstall
make DESTDIR="${srcdir}"/fakeinstall distro-pack-install
}
#check() {
# cd "${srcdir}"/build
# make check
#}
package_libreoffice-fresh-sdk() {
pkgdesc="Software Development Kit for LibreOffice Fresh"
depends=('libreoffice-fresh' 'gcc-libs' 'sh' 'make' 'zip' 'gcc' 'java-environment')
provides=('libreoffice-sdk')
conflicts=('libreoffice-still-sdk')
for dir in $(grep -h ^%dir libreoffice-$_LOver/file-lists/sdk{,_doc}_list.txt); do
install -dm755 "${pkgdir}"/${dir/\%dir/}
done
for file in $(grep -h -v ^%dir libreoffice-$_LOver/file-lists/sdk{,_doc}_list.txt); do
dirname=$(dirname $file)
[[ -d "${pkgdir}"/$dirname ]] || install -dm755 "${pkgdir}"/$dirname
mv "${srcdir}"/fakeinstall/${file} "${pkgdir}"/$file
done
# fix environment path to keep compatibility with other java-environments
sed -i -e "s:\/usr\/lib\/jvm\/java-7-openjdk:\$J2SDKDIR:" \
"${pkgdir}"/usr/lib/libreoffice/sdk/setsdkenv_unix.sh
# fix permissions
find "${pkgdir}"/usr/lib/libreoffice/sdk/examples -type f -exec chmod -x {} +
# add LibreOfficeKit headers; FS#48066
install -dm755 "${pkgdir}"/usr/include/LibreOfficeKit
install -v -m644 "${srcdir}"/libreoffice-$_LOver/include/LibreOfficeKit/* "${pkgdir}"/usr/include/LibreOfficeKit
}
package_libreoffice-fresh() {
pkgdesc="LibreOffice branch which contains new features and program enhancements"
depends=('curl>=7.20.0' 'hunspell>=1.2.8' 'python>=3.7' 'libwpd>=0.9.2' 'libwps'
'neon>=0.28.6' 'pango' 'nspr' 'libjpeg' 'libxrandr' 'libgl'
'libxslt' 'redland' 'hyphen' 'lpsolve' 'gcc-libs' 'sh' 'graphite' 'icu'
'lcms2' 'poppler>=0.24.0' 'libvisio' 'libetonyek' 'libodfgen' 'libcdr'
'libmspub' 'harfbuzz-icu' 'nss' 'clucene' 'hicolor-icon-theme'
'desktop-file-utils' 'shared-mime-info' 'libpagemaker'
'libxinerama' 'libabw' 'libmwaw' 'libe-book' 'libcups'
'liblangtag' 'libexttextcat' 'libcmis' 'liborcus' # 'libfbclient'
'libtommath' 'libzmf' 'libatomic_ops' 'xmlsec' 'gpgme' 'libnumbertext'
'libfreehand' 'libstaroffice' 'libepubgen' 'libqxp' 'libepoxy')
optdepends=('java-runtime: adds java support'
'java-environment: required by extension-wiki-publisher and extension-nlpsolver'
'pstoedit: translates PostScript and PDF graphics into other vector formats'
'libmythes: for use in thesaurus'
'beanshell: interactive java -- good for prototyping/macros'
'libwpg: library for importing and converting WordPerfect Graphics format'
'sane: for scanner access'
'unixodbc: adds ODBC database support'
'gst-plugins-base-libs: for multimedia content, e.g. in Impress'
'libpaper: takes care of papersize'
'postgresql-libs: for postgresql-connector'
'mariadb-libs: for mysql-connector'
'coin-or-mp: required by the Calc solver'
#'gtk2: for GTK2 integration'
'gtk3: for GTK3 integration'
'kio: for KF5 KDE desktop integration')
backup=(etc/libreoffice/sofficerc
etc/libreoffice/bootstraprc
etc/libreoffice/psprint.conf
etc/profile.d/libreoffice-fresh.sh
etc/profile.d/libreoffice-fresh.csh)
provides=('libreoffice' 'libreoffice-en-US')
conflicts=('libreoffice-still')
mv fakeinstall/* ${pkgdir}/
# put configuration files into place
install -dm755 "${pkgdir}"/etc/libreoffice
install -m644 "${pkgdir}"/usr/lib/libreoffice/program/{bootstraprc,sofficerc} \
"${pkgdir}"/etc/libreoffice/
install -m644 "${pkgdir}"/usr/lib/libreoffice/share/psprint/psprint.conf \
"${pkgdir}"/etc/libreoffice/
# install dummy links to make them found by LibO
cd "${pkgdir}"/usr/lib/libreoffice/program/
ln -vsf /etc/libreoffice/{bootstraprc,sofficerc} .
cd "${pkgdir}"/usr/lib/libreoffice/share/psprint/
ln -vsf /etc/libreoffice/psprint.conf .
# allow to preset desired VLC
install -dm755 "${pkgdir}"/etc/profile.d
install -m644 "${srcdir}"/libreoffice-fresh.{sh,csh} "${pkgdir}"/etc/profile.d/
# make pyuno find its modules
install -dm755 "${pkgdir}"/usr/lib/python3.8/site-packages
ln -svf /usr/lib/libreoffice/program/uno.py \
"${pkgdir}"/usr/lib/python3.8/site-packages/uno.py
ln -svf /usr/lib/libreoffice/program/unohelper.py \
"${pkgdir}"/usr/lib/python3.8/site-packages/unohelper.py
# add a symlink required for gnome-documents; FS#51887
# https://lists.freedesktop.org/archives/libreoffice/2016-March/073787.html
ln -svf /usr/lib/libreoffice/program/liblibreofficekitgtk.so \
"${pkgdir}"/usr/lib/liblibreofficekitgtk.so
# cleanup
rm -rf "${pkgdir}"/usr/share/libreoffice/sdk
# add application descriptions
install -dm755 "${pkgdir}"/usr/share/metainfo
install -v -m644 "${srcdir}"/libreoffice-$_LOver/sysui/desktop/appstream-appdata/*.xml \
"${pkgdir}"/usr/share/metainfo
# add kde filemanager templates; FS#61662 - file taken from Debian
install -dm755 "${pkgdir}"/usr/share/templates/.source
install -v -m644 "${srcdir}"/libreoffice-$_LOver/extras/source/shellnew/soffice.* \
"${pkgdir}"/usr/share/templates/.source
cat "${srcdir}"/soffice-template.desktop.in \
| sed -e "s/@APP@/Writer/" \
| sed -e "s/@EXT@/odt/" \
| sed -e "s/@TYPE@/text/" \
> "${pkgdir}"/usr/share/templates/soffice.odt.desktop
cat "${srcdir}"/soffice-template.desktop.in \
| sed -e "s/@APP@/Calc/" \
| sed -e "s/@EXT@/ods/" \
| sed -e "s/@TYPE@/spreadsheet/" \
> "${pkgdir}"/usr/share/templates/soffice.ods.desktop
cat "${srcdir}"/soffice-template.desktop.in \
| sed -e "s/@APP@/Impress/" \
| sed -e "s/@EXT@/odp/" \
| sed -e "s/@TYPE@/presentation/" \
> "${pkgdir}"/usr/share/templates/soffice.odp.desktop
cat "${srcdir}"/soffice-template.desktop.in \
| sed -e "s/@APP@/Draw/" \
| sed -e "s/@EXT@/odg/" \
| sed -e "s/@TYPE@/drawing/" \
> "${pkgdir}"/usr/share/templates/soffice.odg.desktop
# make all i18n lang packages with help section ('1') available to
# fix "F1" not opening translated offline help opening in browser
# see also /usr/lib/libreoffice/help/en-US/langnames.js
echo "var languagesSet = new Set(['en-US','am','ar','ast','bg','bn',\
'bn-IN','bo','bs','ca','ca-valencia','cs','da','de','dz','el',\
'en-GB','en-ZA','eo','es','et','eu','fi','fr','gl','gu','he',\
'hi','hr','hu','id','is','it','ja','ka','km','ko','lo','lt','lv',\
'mk','nb','ne','nl','nn','om','pl','pt','pt-BR','ro','ru','si',\
'sid','sk','sl','sq','sv','ta','tg','tr','ug','uk','vi','zh-CN','zh-TW'])" \
> "${pkgdir}"/usr/lib/libreoffice/help/languages.js
}
Reference in a new issue View git blame Copy permalink