mirror of
https://github.com/archlinuxarm/PKGBUILDs.git
synced 2024-11-08 22:45:43 +00:00
50 lines
1.8 KiB
Bash
50 lines
1.8 KiB
Bash
# Maintainer: David Runge <dvzrv@archlinux.org>
|
|
# Contributor: Ray Rashif <schiv@archlinux.org>
|
|
# Contributor: speps <speps at aur dot archlinux dot org>
|
|
# Contributor: Philipp Überbacher <hollunder at gmx dot at>
|
|
|
|
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
|
|
# - set -DCONFIG_SSE=OFF
|
|
|
|
pkgname=qtractor
|
|
pkgver=0.9.28
|
|
pkgrel=1
|
|
pkgdesc="Audio/MIDI multitrack sequencer"
|
|
arch=(x86_64)
|
|
url="https://qtractor.sourceforge.io/"
|
|
license=(GPL2)
|
|
groups=(pro-audio)
|
|
depends=(glibc gcc-libs hicolor-icon-theme libmad libxcb qt6-base qt6-svg zlib)
|
|
makedepends=(alsa-lib aubio cmake dssi jack ladspa liblo libogg libsamplerate
|
|
libsndfile libvorbis lilv lv2 qt6-tools rubberband suil vst3sdk)
|
|
optdepends=(
|
|
'new-session-manager: for session management'
|
|
'qt6-wayland: for native wayland support'
|
|
)
|
|
provides=(dssi-host ladspa-host lv2-host vst-host vst3-host)
|
|
# NOTE: debug package contains include files of vst3sdk
|
|
# options=(debug)
|
|
source=(https://sourceforge.net/projects/$pkgname/files/$pkgname/$pkgver/$pkgname-$pkgver.tar.gz)
|
|
sha512sums=('db63766bcfd5a744a532d68cbe6f3153f9dd02208bca5098b27cda1cbec694b2981b3eb6a7912324c07327c000087cb5f5ba46dccc96398d051e011ce563fc67')
|
|
b2sums=('aa0d71732b9d214da22a97ca15d0c54eb61b7c35656f827bd0e39f5b55981b0c0d29645d5d3c4280ccba6aab971171615ef099f1cea1f3a8c381ac0dfffd2ca8')
|
|
|
|
build() {
|
|
cmake -DCMAKE_INSTALL_PREFIX=/usr \
|
|
-DCMAKE_BUILD_TYPE=None \
|
|
-DCONFIG_QT6=ON \
|
|
-DCONFIG_SSE=OFF \
|
|
-Wno-dev \
|
|
-B build \
|
|
-S $pkgname-$pkgver
|
|
make VERBOSE=1 -C build
|
|
}
|
|
|
|
package() {
|
|
depends+=(libasound.so libaubio.so libjack.so liblilv-0.so liblo.so libogg.so
|
|
librubberband.so libsamplerate.so libsndfile.so libvorbisenc.so
|
|
libvorbisfile.so libvorbis.so )
|
|
|
|
make DESTDIR="$pkgdir" install -C build
|
|
# docs
|
|
install -vDm 644 $pkgname-$pkgver/{README,README.VST} -t "$pkgdir/usr/share/doc/$pkgname/"
|
|
}
|