mirror of
https://github.com/archlinuxarm/PKGBUILDs.git
synced 2024-11-08 22:45:43 +00:00
55 lines
1.4 KiB
Bash
55 lines
1.4 KiB
Bash
# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
|
|
# Contributor: Ionut Biru <ibiru@archlinux.org>
|
|
|
|
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
|
|
# - patch from debian to detect libatomic usage
|
|
|
|
pkgname=gjs
|
|
pkgver=1.70.0
|
|
pkgrel=3
|
|
epoch=2
|
|
pkgdesc="Javascript Bindings for GNOME"
|
|
url="https://wiki.gnome.org/Projects/Gjs"
|
|
arch=(x86_64)
|
|
license=(GPL)
|
|
depends=(cairo gobject-introspection-runtime js78 dconf readline
|
|
libsysprof-capture)
|
|
makedepends=(gobject-introspection git meson dbus)
|
|
checkdepends=(valgrind xorg-server-xvfb gtk3 gtk4)
|
|
provides=(libgjs.so)
|
|
_commit=da5d5fe74469c799de80117758d79ad694d1116a # tags/1.70.0^0
|
|
source=("git+https://gitlab.gnome.org/GNOME/gjs.git#commit=$_commit"
|
|
build-Link-with-libatomic-if-necessary.patch)
|
|
sha256sums=('SKIP'
|
|
'fcfcc02a65b3917fbdf7ded5ee294ff5fc71225ffe720e42ca0257c7cb14eada')
|
|
|
|
pkgver() {
|
|
cd gjs
|
|
git describe --tags | sed 's/-/+/g'
|
|
}
|
|
|
|
prepare() {
|
|
cd gjs
|
|
patch -p1 -i ../build-Link-with-libatomic-if-necessary.patch
|
|
}
|
|
|
|
build() {
|
|
CFLAGS="${CFLAGS/-O2/-O3} -fno-semantic-interposition"
|
|
CXXFLAGS="${CXXFLAGS/-O2/-O3} -fno-semantic-interposition"
|
|
LDFLAGS+=" -Wl,-Bsymbolic-functions"
|
|
|
|
arch-meson gjs build -D installed_tests=false
|
|
meson compile -C build
|
|
}
|
|
|
|
check() {
|
|
xvfb-run -s '-nolisten local' \
|
|
meson test -C build --print-errorlogs
|
|
}
|
|
|
|
package() {
|
|
depends+=(libreadline.so)
|
|
meson install -C build --destdir "$pkgdir"
|
|
}
|
|
|
|
# vim:set sw=2 et:
|