mirror of
https://github.com/archlinuxarm/PKGBUILDs.git
synced 2024-09-19 22:08:32 +00:00
45 lines
1.2 KiB
Bash
45 lines
1.2 KiB
Bash
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
|
|
# Contributor: Jan de Groot <jgc@archlinux.org>
|
|
|
|
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
|
|
# - configure with --enable-compile-warnings=no
|
|
|
|
pkgname=yelp
|
|
pkgver=3.30.0
|
|
pkgrel=1
|
|
pkgdesc="Get help with GNOME"
|
|
url="https://wiki.gnome.org/Apps/Yelp"
|
|
license=(GPL)
|
|
arch=(x86_64)
|
|
depends=(webkit2gtk yelp-xsl libxslt xz bzip2)
|
|
makedepends=(intltool gtk-doc itstool autoconf-archive git xorg-server-xvfb appstream-glib)
|
|
groups=(gnome)
|
|
_commit=25c629c029ff9f65f767233f7c97532c25818af6 # tags/3.30.0^0
|
|
source=("git+https://gitlab.gnome.org/GNOME/yelp.git#commit=$_commit")
|
|
sha256sums=('SKIP')
|
|
|
|
pkgver() {
|
|
cd $pkgname
|
|
git describe --tags | sed 's/-/+/g'
|
|
}
|
|
|
|
prepare() {
|
|
cd $pkgname
|
|
NOCONFIGURE=1 ./autogen.sh
|
|
}
|
|
|
|
build() {
|
|
cd $pkgname
|
|
./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
|
|
--disable-static --enable-gtk-doc --enable-compile-warnings=no
|
|
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
|
|
|
|
# Documentation generation segfaults without X11
|
|
xvfb-run -a -n 81 -s "-extension GLX -screen 0 1280x1024x24" make
|
|
}
|
|
|
|
package() {
|
|
cd $pkgname
|
|
make DESTDIR="$pkgdir" install
|
|
}
|