mirror of
https://github.com/archlinuxarm/PKGBUILDs.git
synced 2024-09-19 22:08:32 +00:00
62 lines
2 KiB
Bash
62 lines
2 KiB
Bash
# $Id$
|
|
# Maintainer: Andreas Radke <andyrtr@archlinux.org>
|
|
|
|
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
|
|
# - do not use LLINT assembly for v5/v6
|
|
|
|
pkgname=webkit2gtk
|
|
pkgver=2.6.1
|
|
pkgrel=2
|
|
pkgdesc="GTK+ Web content engine library"
|
|
arch=(i686 x86_64)
|
|
url="http://webkitgtk.org/"
|
|
license=(custom)
|
|
depends=(libxt libxslt sqlite libsoup enchant libgl geoclue2 gst-plugins-base-libs
|
|
libsecret libwebp harfbuzz-icu gtk3)
|
|
makedepends=(gtk3 gtk2 gperf gobject-introspection python2 mesa ruby gtk-doc cmake python)
|
|
optdepends=('gtk2: Netscape plugin support'
|
|
'gst-plugins-base: free media decoding'
|
|
'gst-plugins-good: media decoding'
|
|
'gst-libav: nonfree media decoding')
|
|
options=(!emptydirs)
|
|
source=(http://webkitgtk.org/releases/webkitgtk-${pkgver}.tar.xz
|
|
fix-pretty-quotes.patch)
|
|
sha256sums=('c846a662762dd79c26e77fa36348e706d217d1385bb2dbdcfc28a5a1476c6d54'
|
|
'56316228bbbf0b7ebcbe210a35120f4e72cb9c1b680dd82cc2bde0f4549245e6')
|
|
|
|
prepare() {
|
|
mkdir build
|
|
|
|
cd webkitgtk-$pkgver
|
|
patch -Np0 -i ../fix-pretty-quotes.patch
|
|
sed -i '1s/python$/&2/' Tools/gtk/generate-gtkdoc
|
|
rm -r Source/ThirdParty/gtest/
|
|
rm -r Source/ThirdParty/qunit/
|
|
}
|
|
|
|
build() {
|
|
cd build
|
|
|
|
# do not use LLINT assembly for v5/v6
|
|
[[ $CARCH == "arm" || $CARCH == "armv6h" ]] && CONFIG="-DENABLE_LLINT_C_LOOP=1"
|
|
|
|
cmake -DPORT=GTK -DCMAKE_BUILD_TYPE=Release \
|
|
-DCMAKE_SKIP_RPATH=ON -DCMAKE_INSTALL_PREFIX=/usr \
|
|
-DLIB_INSTALL_DIR=/usr/lib -DLIBEXEC_INSTALL_DIR=/usr/lib/webkit2gtk-4.0 \
|
|
-DENABLE_GTKDOC=ON $CONFIG ../webkitgtk-$pkgver
|
|
make
|
|
}
|
|
|
|
package() {
|
|
cd build
|
|
make DESTDIR="$pkgdir" install
|
|
|
|
install -m755 -d "$pkgdir/usr/share/licenses/webkit2gtk"
|
|
cd "$srcdir/webkitgtk-$pkgver/Source"
|
|
for f in $(find -name 'COPYING*' -or -name 'LICENSE*'); do
|
|
echo $f >> "$pkgdir/usr/share/licenses/webkit2gtk/LICENSE"
|
|
cat $f >> "$pkgdir/usr/share/licenses/webkit2gtk/LICENSE"
|
|
echo "" >> "$pkgdir/usr/share/licenses/webkit2gtk/LICENSE"
|
|
done
|
|
}
|