PKGBUILDs/community/afl/PKGBUILD
2015-12-17 00:54:28 +00:00

41 lines
1.3 KiB
Bash

# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Contributor: spider-mario <spidermario@free.fr>
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
# - make with AFL_NOX86=1
pkgname=afl
pkgver=1.96b
pkgrel=1
pkgdesc='Security-oriented fuzzer using compile-time instrumentation and genetic algorithms'
url="http://lcamtuf.coredump.cx/afl/"
arch=('i686' 'x86_64')
license=('Apache')
depends=('glibc' 'bash')
optdepends=(
'gcc: gcc instrumentation support'
'clang: clang instrumentation support'
'llvm: experimental clang-fast instrumentation support'
'gnuplot: graph plotting support'
)
makedepends=('clang' 'llvm' 'gcc')
provides=('american-fuzzy-lop')
replaces=('american-fuzzy-lop')
options=('!emptydirs' '!strip')
source=(${pkgname}-${pkgver}.tgz::http://lcamtuf.coredump.cx/${pkgname}/releases/${pkgname}-${pkgver}.tgz)
sha512sums=('a55d89ffe9c89586b70f8a9ab80330cc0511f453d5918045ec06289093ca5321611b08a522bb058e3c16ddc9b5d5ec221ce1cab9819b79f4738cba15f2aadff0')
build() {
cd ${pkgname}-${pkgver}
make PREFIX=/usr AFL_NOX86=1
make -C llvm_mode PREFIX=/usr
}
package() {
cd ${pkgname}-${pkgver}
make PREFIX=/usr AFL_NOX86=1 DESTDIR="${pkgdir}" install
install -Dm 644 llvm_mode/README.llvm "${pkgdir}/usr/share/doc/${pkgname}/README.llvm"
}
# vim: ts=2 sw=2 et: