mirror of
https://github.com/archlinuxarm/PKGBUILDs.git
synced 2024-09-19 22:08:32 +00:00
73 lines
2.6 KiB
Bash
73 lines
2.6 KiB
Bash
# Maintainer: Sven-Hendrik Haase <sh@lutzhaase.com>
|
|
# Maintainer: Antonio Rojas <arojas@archlinux.org>
|
|
# Contributor: Imanol Celaya <ornitorrincos@archlinux-es.org>
|
|
# Contributor: Lukas Jirkovsky <l.jirkovsky@gmail.com>
|
|
# Contributor: Dan Vratil <progdan@progdansoft.com>
|
|
# Contributor: thotypous <matiasΘarchlinux-br·org>
|
|
# Contributor: delor <bartekpiech gmail com>
|
|
|
|
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
|
|
# - drop valgrind optdepend
|
|
|
|
buildarch=12
|
|
|
|
pkgname=qtcreator
|
|
pkgver=4.9.0
|
|
_clangver=8.0.0
|
|
pkgrel=1
|
|
pkgdesc='Lightweight, cross-platform integrated development environment'
|
|
arch=(x86_64)
|
|
url='https://www.qt.io'
|
|
license=(LGPL)
|
|
depends=(qt5-tools qt5-quickcontrols qt5-quickcontrols2 qt5-webengine clang=$_clangver qbs clazy syntax-highlighting desktop-file-utils)
|
|
makedepends=(llvm python)
|
|
options=(docs)
|
|
optdepends=('qt5-doc: integrated Qt documentation'
|
|
'qt5-examples: welcome page examples'
|
|
'qt5-translations: for other languages'
|
|
'gdb: debugger'
|
|
'cmake: cmake project support'
|
|
'x11-ssh-askpass: ssh support'
|
|
'git: git support'
|
|
'mercurial: mercurial support'
|
|
'bzr: bazaar support')
|
|
source=("https://download.qt.io/official_releases/qtcreator/${pkgver%.*}/$pkgver/qt-creator-opensource-src-$pkgver.tar.xz"
|
|
qtcreator-clang-plugins.patch)
|
|
sha256sums=('46ee1992531b769450f8be96cf63520b609d7dd305df345d7cd8216ac396e6a8'
|
|
'149ffcd0ab7c53605951c66dba707ff7e0dc17136c921f1a668fc392c5a7f3f2')
|
|
|
|
prepare() {
|
|
mkdir -p build
|
|
|
|
cd qt-creator-opensource-src-$pkgver
|
|
# fix hardcoded libexec path
|
|
sed -e 's|libexec\/qtcreator|lib\/qtcreator|g' -i qtcreator.pri
|
|
# use system qbs
|
|
rm -r src/shared/qbs
|
|
# Load analyzer plugins on demand, since upstream clang doesn't link to all plugins
|
|
# see http://code.qt.io/cgit/clang/clang.git/commit/?id=7f349701d3ea0c47be3a43e265699dddd3fd55cf
|
|
# and https://bugs.archlinux.org/task/59492
|
|
patch -p1 -i ../qtcreator-clang-plugins.patch
|
|
}
|
|
|
|
build() {
|
|
cd build
|
|
|
|
qmake LLVM_INSTALL_DIR=/usr QBS_INSTALL_DIR=/usr \
|
|
KSYNTAXHIGHLIGHTING_LIB_DIR=/usr/lib KSYNTAXHIGHLIGHTING_INCLUDE_DIR=/usr/include/KF5/KSyntaxHighlighting \
|
|
CONFIG+=journald QMAKE_CFLAGS_ISYSTEM=-I \
|
|
DEFINES+=QBS_ENABLE_PROJECT_FILE_UPDATES \
|
|
"$srcdir"/qt-creator-opensource-src-$pkgver/qtcreator.pro
|
|
make
|
|
make docs
|
|
}
|
|
|
|
package() {
|
|
cd build
|
|
|
|
make INSTALL_ROOT="$pkgdir/usr/" install
|
|
make INSTALL_ROOT="$pkgdir/usr/" install_docs
|
|
|
|
install -Dm644 "$srcdir"/qt-creator-opensource-src-$pkgver/LICENSE.GPL3-EXCEPT "$pkgdir"/usr/share/licenses/qtcreator/LICENSE.GPL3-EXCEPT
|
|
}
|