mirror of
https://github.com/archlinuxarm/PKGBUILDs.git
synced 2024-09-19 22:08:32 +00:00
51 lines
1.5 KiB
Bash
51 lines
1.5 KiB
Bash
# Maintainer: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
|
|
# Contributor: Dave Reisner <dreisner@archlinux.org>
|
|
# Contributor: Thomas Bächler <thomas@archlinux.org>
|
|
|
|
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
|
|
# - removed -mtune, changed -march to v8/v7/v6/v5 compat
|
|
|
|
pkgname=mkinitcpio-busybox
|
|
pkgver=1.30.1
|
|
pkgrel=1
|
|
pkgdesc='Base initramfs tools'
|
|
arch=(x86_64)
|
|
url="http://www.busybox.net/"
|
|
license=(GPL)
|
|
depends=(glibc)
|
|
options=(!buildflags)
|
|
source=(https://busybox.net/downloads/busybox-$pkgver.tar.bz2{,.sig}
|
|
config)
|
|
sha256sums=('3d1d04a4dbd34048f4794815a5c48ebb9eb53c5277e09ffffc060323b95dfbdc'
|
|
'SKIP'
|
|
'e35b09565b87d0a35c8085b4d34477d8795d23fb969a674b5d7f9579279dd7d4')
|
|
validpgpkeys=('C9E9416F76E610DBD09D040F47B70C55ACC9965B') # Denis Vlasenko <vda.linux@googlemail.com>
|
|
|
|
prepare() {
|
|
cd "busybox-$pkgver"
|
|
|
|
if [ ${CARCH} = "aarch64" ]; then
|
|
ARMCARCH="armv8-a"
|
|
elif [ ${CARCH} = "armv7h" ]; then
|
|
ARMCARCH="armv7-a -mfloat-abi=hard -mfpu=vfpv3-d16"
|
|
elif [ ${CARCH} = "armv6h" ]; then
|
|
ARMCARCH="armv6 -mfloat-abi=hard -mfpu=vfp"
|
|
else
|
|
ARMCARCH="armv5te"
|
|
fi
|
|
|
|
local safeflags="-march=${ARMCARCH} -Os -pipe -fno-strict-aliasing"
|
|
|
|
sed 's|^\(CONFIG_EXTRA_CFLAGS\)=.*|\1="'"$safeflags"'"|' "$srcdir/config" > .config
|
|
}
|
|
|
|
build() {
|
|
# reproducible build
|
|
export KCONFIG_NOTIMESTAMP=1
|
|
make -C "busybox-$pkgver"
|
|
}
|
|
|
|
package() {
|
|
install -Dm755 "$srcdir/busybox-$pkgver/busybox" "$pkgdir/usr/lib/initcpio/busybox"
|
|
}
|