mirror of
https://github.com/archlinuxarm/PKGBUILDs.git
synced 2024-11-18 22:54:00 +00:00
84 lines
3.3 KiB
Bash
84 lines
3.3 KiB
Bash
# Maintainer: Bruno Pagani <archange@archlinux.org>
|
|
# Maintainer: Filipe Laíns (FFY00) <lains@archlinux.org>
|
|
# Maintainer: Frederik Schwan <freswa at archlinux dot org>
|
|
# Contributor: Mirco Tischler <mt-ml at gmx dot de>
|
|
|
|
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
|
|
# - remove depends on libsmbios, efivar, fwupd-efi
|
|
# - remove makedepends on valgrind, gnu-efi-libs, tpm2-tss
|
|
# - meson with -Dplugin_dell=false (smbios dependency)
|
|
# - meson with -Dplugin_uefi_capsule=false -Dplugin_uefi_pk=false -Dplugin_redfish=false -Dplugin_nvme=false (efivar, gnu-efi-libs dependency)
|
|
# - meson with -Dplugin_msr=false
|
|
# - meson with -Dplugin_intel_spi=false
|
|
# - replace efi_sbat_distro_url with ALARM URL
|
|
|
|
pkgname=fwupd
|
|
pkgver=1.7.0
|
|
pkgrel=1
|
|
pkgdesc="Simple daemon to allow session software to update firmware"
|
|
arch=(x86_64)
|
|
url="https://github.com/fwupd/fwupd"
|
|
license=(LGPL)
|
|
depends=(libxmlb python libgusb
|
|
polkit shared-mime-info tpm2-tss flashrom
|
|
libjcat gcab hicolor-icon-theme
|
|
libarchive.so libcurl.so
|
|
libjson-glib-1.0.so libgudev-1.0.so libmm-glib.so
|
|
libqmi-glib.so libprotobuf-c.so)
|
|
optdepends=(
|
|
'udisks2: UEFI firmware upgrade support'
|
|
)
|
|
makedepends=(meson gobject-introspection gtk-doc
|
|
python-cairo noto-fonts noto-fonts-cjk python-gobject vala
|
|
bash-completion python-pillow help2man)
|
|
checkdepends=(umockdev)
|
|
provides=(libfwupd.so)
|
|
backup=('etc/fwupd/daemon.conf'
|
|
'etc/fwupd/redfish.conf'
|
|
'etc/fwupd/remotes.d/dell-esrt.conf'
|
|
'etc/fwupd/remotes.d/fwupd-tests.conf'
|
|
'etc/fwupd/remotes.d/lvfs-testing.conf'
|
|
'etc/fwupd/remotes.d/lvfs.conf'
|
|
'etc/fwupd/remotes.d/vendor-directory.conf'
|
|
'etc/fwupd/remotes.d/vendor.conf'
|
|
'etc/fwupd/thunderbolt.conf'
|
|
'etc/fwupd/uefi_capsule.conf'
|
|
)
|
|
source=("https://people.freedesktop.org/~hughsient/releases/${pkgname}-${pkgver}.tar.xz"{,.asc})
|
|
sha256sums=('6c4d5aa55abe8814810094f6e18db63a65539666e682aa9d050ce6028c2542c4'
|
|
'SKIP')
|
|
validpgpkeys=(163EB50119225DB3DF8F49EA17ACBA8DFA970E17) # Richard Hughes <richard@hughsie.com>
|
|
|
|
build() {
|
|
arch-meson ${pkgname}-${pkgver} build \
|
|
-D b_lto=false \
|
|
-D plugin_modem_manager=true \
|
|
-D plugin_intel_spi=false \
|
|
-D lzma=true \
|
|
-D docs=gtkdoc \
|
|
-D plugin_flashrom=true \
|
|
-D supported_build=true \
|
|
-D efi_sbat_distro_id='arch' \
|
|
-D efi_sbat_distro_summary='Arch Linux' \
|
|
-D efi_sbat_distro_pkgname=${pkgname} \
|
|
-D efi_sbat_distro_version=${pkgver} \
|
|
-D efi_sbat_distro_url="https://archlinuxarm.org/packages/${CARCH}/${pkgname}" \
|
|
-Dplugin_dell=false -Dplugin_uefi_capsule=false -Dplugin_uefi_pk=false -Dplugin_redfish=false -Dplugin_nvme=false -Dplugin_msr=false
|
|
meson compile -C build
|
|
}
|
|
|
|
check() {
|
|
meson test -C build
|
|
}
|
|
|
|
package() {
|
|
DESTDIR="${pkgdir}" meson install -C build
|
|
# Fixup mode to match polkit
|
|
install -d -o root -g 102 -m 750 "${pkgdir}"/usr/share/polkit-1/rules.d
|
|
# Remove the tests
|
|
rm -r "${pkgdir}"/usr/share/installed-tests/
|
|
#mv "${pkgdir}"/usr/bin/{,fwupd-}dbxtool
|
|
#mv "${pkgdir}"/usr/share/man/man1/{,fwupd-}dbxtool.1
|
|
# Remove msr module-load config as it is built-in
|
|
rm -f "${pkgdir}"/usr/lib/modules-load.d/fwupd-msr.conf
|
|
}
|